Function Reference

首页  后退  前进

GUICtrlCreateAvi

 

创建 AVI 视频控件.

 

GUICtrlCreateAvi ( filename, subfileid, left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )

参数

filename

视频文件名. 仅支持 .avi 格式文件.

subfileid

子文件 ID. 若该文件只有一个视频, 则设置为 0.

left

控件左侧的位置. 若此值为 -1, 则根据 GUICoordMode() 的设置计算左侧位置.

top

控件上方的位置. 若此值为 -1, 则根据 GUICoordMode() 的设置计算顶部位置.

width

[可选] 控件的宽度(默认使用先前的宽度).

height

[可选] 控件的高度(默认使用先前的高度).

style

[可选] 控件的样式. 查看附录 GUI 控件样式表.

默认样式 (-1) : $ACS_TRANSPARENT

除非指定 $ACS_NONTRANSPARENT, 否则总是使用 $ACS_TRANSPARENT.

exStyle

[可选] 控件的扩展样式. 查看附录 扩展样式表.

返回值

成功:

返回新的控件标识符 (控件 ID).

失败:

返回 0.

备注

要获得控件的值, 查看 GUICtrlRead() 函数帮助页.

设置或者修改控件信息, 参考 GUICtrlUpdate...()

 

要在控件被创建后立即播放该视频剪辑,则添加 $ACS_AUTOPLAY 样式.

使用 GUICtrlSetState() 设置状态值为 1 或 0, 即可播放或停止视频剪辑. 见示例.

 

要在默认样式上添加新样式, 可使用 BitOR($GUI_SS_DEFAULT_AVI, 新样式,...) 语句.

使用上面列出的值必须将 #include <AVIConstants.au3> 语句写入脚本中.

 

默认大小为 $GUI_DOCKSIZE.

相关

GUICoordMode (option), GUICtrlUpdate..., GUIGetMsg

函数示例

#include <GUIConstantsEx.au3>
Example()
Func Example()
    ; Create a GUI with various controls.
    Local $hGUI = GUICreate("Example", 300, 200)
    ; Create an animation control.
    Local $idAnimation = GUICtrlCreateAvi(@SystemDir & "\shell32.dll", 165, 15, 0, 300)
    Local $idStart = GUICtrlCreateButton("Start", 60, 150, 85, 25)
    Local $idStop = GUICtrlCreateButton("Stop", 160, 150, 85, 25)
    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)
    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $idStart ; Start the animation.
                GUICtrlSetState($idAnimation, $GUI_AVISTART)
            Case $idStop ; Stop the animation.
                GUICtrlSetState($idAnimation, $GUI_AVISTOP)
        EndSwitch
    WEnd
    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)
EndFunc   ;==>Example

----------------------------------------