GUICtrlCreateTab
创建选项卡(Tab)控件.
GUICtrlCreateTab ( left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
参数
left
|
控件左侧的位置. 若此值为 -1, 则根据 GUICoordMode() 的设置计算左侧位置.
|
top
|
控件上方的位置. 若此值为 -1, 则根据 GUICoordMode() 的设置计算顶部位置.
|
width
|
[可选] 控件的宽度(默认使用先前的宽度).
|
height
|
[可选] 控件的高度(默认使用先前的高度).
|
style
|
[可选] 控件的样式. 查看附录 GUI 控件样式表.
默认样式 ( -1) : 无.
强制样式 : $TCS_TOOLTIPS, $WS_TABSTOP, $WS_CLIPSIBLINGS
|
exStyle
|
[可选] 控件的扩展样式. 查看附录 扩展样式表.
|
返回值
成功:
|
返回控件标识符(控件ID).
|
失败:
|
返回 0.
|
备注
本函数只是创建标签(Tab)控件(容器), 其中的标签页项目还要使用 GUICtrlCreate... 创建控件类函数创建.
重要的是标签页项目创建完毕后, 要使用 GUICtrlCreateTabItem("") 语句关闭选项卡结构.
设置或者修改控件信息, 参考 GUICtrlUpdate...() 控件更新控件更新类函数.
要在默认样式上添加新样式, 可使用 BitOR($GUI_SS_DEFAULT_TAB, 新样式,...) 语句.
使用默认值要在脚本中添加 #include <TabConstants.au3> 语句.
默认大小为 $GUI_DOCKSIZE.
一个窗口只能创建一个标签页控件. 但可以创建若干各持一个选项卡控件的子窗口.
相关
GUICoordMode (Option), GUICtrlCreate..., GUICtrlCreateTabItem, GUICtrlUpdate..., GUIGetMsg
函数示例
#include <GUIConstantsEx.au3>
Example()
Func Example()
GUICreate("My GUI Tab") ; will create a dialog box that when displayed is centered
GUISetBkColor(0x00E0FFFF)
GUISetFont(9, 300)
GUICtrlCreateTab(10, 10, 200, 100)
GUICtrlCreateTabItem("tab0")
GUICtrlCreateLabel("label0", 30, 80, 50, 20)
GUICtrlCreateButton("OK0", 20, 50, 50, 20)
GUICtrlCreateInput("default", 80, 50, 70, 20)
GUICtrlCreateTabItem("tab----1")
GUICtrlCreateLabel("label1", 30, 80, 50, 20)
GUICtrlCreateCombo("", 20, 50, 60, 120)
GUICtrlSetData(-1, "Trids|CyberSlug|Larry|Jon|Tylo|guinness", "Jon") ; default Jon
GUICtrlCreateButton("OK1", 80, 50, 50, 20)
GUICtrlCreateTabItem("tab2")
GUICtrlSetState(-1, $GUI_SHOW) ; will be display first
GUICtrlCreateLabel("label2", 30, 80, 50, 20)
GUICtrlCreateButton("OK2", 140, 50, 50)
GUICtrlCreateTabItem("") ; end tabitem definition
GUICtrlCreateLabel("label3", 20, 130, 50, 20)
GUISetState(@SW_SHOW)
Local $idMsg
; Loop until the user exits.
While 1
$idMsg = GUIGetMsg()
If $idMsg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd
EndFunc ;==>Example
----------------------------------------
|