Function GUISetStyle

Function Reference

首页后退前进

GUISetStyle

调整窗口样式.

GUISetStyle ( Style [, ExStyle [, winhandle]] )

参数

style

指定窗口的显示样式. 见附录 GUI Control Styles Appendix.

指定 -1 为不调整

exStyle

[可选] 指定窗口的扩展样式. 见下面 Extended Style Table. 默认值(default) -1.

使用 -1 为不调整.

winhandle

[可选] 由 GUICreate() 函数返回的窗口句柄 (默认为先前使用的窗口).

返回值

成功:	返回 1.
失败:	返回 0.

备注

不检查任何样式值, 也不与以定义的控件互动. 这是因为设计者用来处理兼容性.

相关

函数示例

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Example()
Func Example()
    GUICreate("Gui Style", 260, 100)
    Local $idButton = GUICtrlCreateButton("Set Style", 45, 50, 150, 20)
    GUISetState(@SW_SHOW)
    Local $bNewStyle = False, $idMsg
    While 1
        $idMsg = GUIGetMsg()
        Switch $idMsg
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $idButton
                If Not $bNewStyle Then
                    GUISetStyle(BitOR($WS_POPUPWINDOW, $WS_THICKFRAME), BitOR($WS_EX_CLIENTEDGE, $WS_EX_TOOLWINDOW))
                    GUICtrlSetData($idButton, 'Undo Style')
                    $bNewStyle = True
                Else
                    GUISetStyle(BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU), 0)
                    GUICtrlSetData($idButton, 'Set Style')
                    $bNewStyle = False
                EndIf
        EndSwitch
    WEnd
    GUIDelete()
EndFunc   ;==>Example

----------------------------------------