Команда ontop

Описание команды

ontop

Изменяет атрибут окна "Поверх всех окон".

ontop=Number, ||$Class или#Title или@Handle||Condition||<info>

Параметры:

	1-й обязательный параметр.
Number	Условие. Где Number: 0 - отключить "Поверх всех окон". 1 - включить "Поверх всех окон". 2 - принять атрибут от окна 3-го параметра. 4 - если у окна есть атрибут "Поверх...", то снимается; если нет атрибута, то устанавливается.
	Дополнительные параметры:
$Class или #Title или @Handle	Окно. По умолчанию активного окна или класс Total Commander. • $Class - класс окна. • #Title - заголовок окна. • @Handle - дескриптор окна.
Condition	Проверка. Параметр &Number($Class/#Title) проверяет атрибут у заданного окна (по умолчанию активного), где Number: 0 - если у заданного окна нет атрибута "Поверх всех окон". 1 - если у заданного окна есть атрибут "Поверх всех окон". 2 - принимает атрибута у заданного окна. Если необходима проверка с неактивным окном, то после &Number прописывается $Class или #Title.
<info>	Получение различной информации. см. Дополнение №10.

Примечания:

По умолчанию атрибут будет установлен активному окну.
Для запуска команды вместе с запуском Total Commander см. Дополнение №4.

В параметрах команды может использоваться:
• GLOBALNAME - информация, получаемая из других команд через глобальные переменные см. Дополнение №23
• значения переменных $var_... команды exect

См. также:

activ, amenu, buttn, iconw, keybd, mxmnz, redrw, rsize, smenu, ssize, thide, title, tityn, trans, wdrag, whide, wmenu, wpull, wshow

Примеры:
Как создать кнопку?

%Z autrn=1||0 start=%%COMMANDER_EXE%%||/S=L:PTCTorrent||%P%N buttn=TLister||x|$w ontop=2||$TLister||$2 autrn=0||0 ;; просмотреть torrent файл под курсором в Lister с помощью плагина TCTorrent в отдельном потоке (комментируя и восстанавливая записи в autorun.cfg и устанавливая поверх всех окон, если TC имеет такой атрибут)

%Z autrn=1||0 start=%%COMMANDER_EXE%%||/S=L||%P%N buttn=TLister||x|$w ontop=2||$TLister||$2 autrn=0||0 ;; просмотр файла под курсором в отдельном потоке

<IF> [info=x470] = 0 <THEN> ssize=1 tcimg=$p0 elmof=1,2,4,12 tcimg=$cm910|2903|305~~$p1 wpull=@W/3,0,@W/3,@H-55 ontop=1 <ELSE> tcimg=$p0~~$cm909|2903|305 elmon=1,2,4,12 tcimg=$p1 rsize=1 ontop=0 <ENDIF> ;; переключение между размерами окна TC + увеличение 100% и восстановление 50% активной панели + отключение ряда элементов окна и восстановление

<TRAY=•~~CTRL+*~~-~~поверх/не~~поверх~~активное~~окно@CRLF•~~ESC~~-~~выход||3||%%TCIMG_PATH%%\TCIMG.dll,5> <PRESS=11,6A> ontop=4 <PRESS=1B> :EXIT: ;; установить/снять атрибут "Поверх всех окон" активного окна. (работает после запуска команды и по нажатию клавиш CTRL + * , выход по ESC, при работе отображается заданная иконка в трее с подсказкой

<TRAY=•~~CTRL+*~~-~~поверх/не~~поверх~~активное~~окно@CRLF•~~ESC~~-~~выход||3||2> <PRESS=11,6A> ontop=4 <PRESS=1B> :EXIT: ;; установить/снять атрибут "Поверх всех окон" активного окна. (работает после запуска команды и по нажатию клавиш CTRL + * , выход по ESC, при работе отображается иконка в трее с подсказкой, иконка в TCIMG.ini в [ProcessIcon] ключ 2

<TRAY=•~~CTRL+*~~-~~поверх/не~~поверх~~активное~~окно@CRLF•~~ESC~~-~~выход> <PRESS=11,6A> ontop=4 <PRESS=1B> :EXIT: ;; установить/снять атрибут "Поверх всех окон" активного окна. (работает после запуска команды и по нажатию клавиш CTRL + * , выход по ESC, при работе отображается иконка в трее)

global wntxt=3||infwt<2> sends=GLOBALWNTXT<1>??-6= ontop=4||@GLOBALSENDS<2> ;; выбрать окно по нажатию Shift и установить/снять атрибут "Поверх всех окон"

ontop=0 ;; снять у активного окна атрибут "Поверх всех окон"

ontop=0||$TLister||&0 ;; снять у запущенного листера атрибут "Поверх всех окон", если Total Commander не имеет атрибута "Поверх всех окон"

ontop=0||$TLister||&1 ;; снять у запущенного листера атрибут "Поверх всех окон", если Total Commander имеет атрибут "Поверх всех окон"

ontop=1 ;; установить активному окну атрибут "Поверх всех окон"

ontop=1||$TLister||&0 ;; установить запущенному листеру атрибут "Поверх всех окон", если Total Commander не имеет атрибута "Поверх всех окон"

ontop=1||$TLister||&1 ;; установить запущенному листеру атрибут "Поверх всех окон", если Total Commander имеет атрибут "Поверх всех окон"

ontop=1||$TTOTAL_CMD ;; установить Total Commander атрибут "Поверх всех окон"

ontop=2||$TLister||&2 ;; установить/снять у запущенного листера атрибут "Поверх всех окон", относительно атрибута Total Commander

ontop=4 ;; установить/снять атрибут "Поверх всех окон" для активного окна

slist=PS<"C:\Save"//1//0//*.torrent>||##path<6> GLOBALSLIST<b> sends=$GLOBALARRAY??-1||eline<"C:\Save\"!!> <FOR> 1 <TO> GLOBALSENDS<0> autrn=1||0 start=%%COMMANDER_EXE%%||/S=L:PTCTorrent||GLOBALSENDS<:INDEX:> buttn=TLister||x|$w ontop=2||$TLister||$2 autrn=0||0 buttn=TLister||x|$e <NEXT> ;; просмотреть поочерёдно torrent файлы выбранные в диалоговом окне из папки "C:\Save\" в Lister с помощью плагина TCTorrent в отдельном потоке (комментируя и восстанавливая записи в autorun.cfg и устанавливая поверх всех окон, если TC имеет такой атрибут)

start=%%COMMANDER_PATH%%\AkelFiles\Tools\RegExp\RegExp.exe ontop=1||#RegExp ;; запустить программу RegExp.exe и установить атрибут "Поверх всех окон"

start=%%COMMANDER_PATH%%\AkelFiles\Tools\RegExp\RegExp.exe trans=230||#RegExp ontop=1||#RegExp ;; запустить программу RegExp.exe, сделать окно прозрачным на 10% и установить атрибут "Поверх всех окон"

start=D:\Test\skf.exe||%P%N ontop=1||#Silent~~key~~finder ;; открыть файл под курсором в программе skf и установить атрибут "поверх всех окон"

swcmd=ontop=1||$TTOTAL_CMD¦¦ontop=0||$TTOTAL_CMD¦¦OnTop ;; поверх всех окон Total Commander Вкл/Выкл

swcmd=ontop=1||$TTOTAL_CMD¦¦ontop=0||$TTOTAL_CMD¦¦TCposition ;; установить / снять атрибут "Поверх всех окон" Total Commander

swcmd=ssize=1??tcimg=$p0??tcimg=$cm910|2903|305??tcimg=$p1??wpull=@W/3,0,@W/3,@H-55??ontop=1¦¦tcimg=$p0??tcimg=$cm909|2903|305??tcimg=$p1??rsize=1??ontop=0¦¦ResHW100_50 ;; переключение между размерами окна TC + увеличение 100% и восстановление 50% активной панели

swcmd=ssize=1??tcimg=$p0??tcimg=$cm910|2903|305??tcimg=$p1??wpull=@W/3,0,@W/3,@H-55??tcimg=$p4??elmof=1,2,4,12??tcimg=$p5??ontop=1¦¦tcimg=$p0??tcimg=$cm909|2903|305??tcimg=$p1??tcimg=$p4??elmon=1,2,4,12??tcimg=$p5??rsize=1??ontop=0¦¦ResHW100_50_2 ;; переключение между размерами окна TC + увеличение 100% и восстановление 50% активной панели + отключение ряда элементов окна и восстановление

swcmd=ssize=1÷÷wpull=@W/3,0,@W/3,@H-55÷÷ontop=1¦¦rsize=1÷÷ontop=0¦¦VaskamyHW ;; переключение между размерами окна TC и восстановлением

swcmd=ssize=1÷÷wpull=0,0,@W,@H÷÷ontop=1||rsize=1÷÷ontop=0||MaxResTC ;; развернуть/восстановить окно Total Commander

wpull=@W/3,(@H-1025)/2,@W/3,1025 ontop=1 ;; уменьшение окна Total Commander по горизонтали до размера 30% от ширины монитора, центрировать его по ширине середины монитора, высота 1025 + поверх всех окон

wpull=@W/3,10,@W/3,@H-55 ontop=1 ;; уменьшение окна Total Commander по горизонтали до размера 30% от ширины монитора, центрировать его по ширине середины монитора, отступ сверху 10, высота меньше на 55 от высоты монитора + поверх всех окон