Описание команды


txtsp

Разбить текстовый файл и сохранить элементы (массива) в файлы.

txtsp=FileTXT||Path, %p, %t||Mode, ||owrite<>||Dialogs||clpget||upd<>||<info>||<xinfo>||namesplit<>||linesp<>||string[]||enum[]||namec<>||tcg<>||code<>||nozero<>

Параметры:

1-й обязательный параметр.
FileTXTПуть. FileTXT - полный путь к текстовому файлу. (%P%N, c:\Test\File.txt) см. Дополнение №7.
2-й обязательный параметр.
Path, %p, %tПуть. Path - путь назначения, где создаются файлы с частями текстового файла.
3-й обязательный параметр.
ModeРежим разбивки файла. Параметр Mode(!!Parameters), где: Mode
  1 - построчная разбивка.
  Может использоваться три необязательных параметра Count!!Start!!End, разделённые !! :
    1) Count - по сколько строк разбивать (по умолчанию 1).
         =Count - разбивать на равное количество строк.
         Min~Max - диапазон строк, файл разбивается случайным количеством строк в заданном диапазоне.
    2) Start - с какой строки начать (по умолчанию с 1-й).
    3) End - до какой строки разбивать (по умолчанию до конца).

  2 - разбивка INI файла по секциям.
  Может использоваться необязательный параметр:
    1 - к имени прибавляется имя секции.

  3 - разбивка INI файла по секциям (сохранение комментариев перед секциями).
  Может использоваться необязательный параметр:
    1 - к имени прибавляется имя секции.

  4 - разбивка по фрагментам, получаемых с помощью регулярного выражения.
  В параметре прописывается:
     • RegExp регулярное выражение.
     • ??Key - ключ из TCIMG.ini из секции [FormatUser], в котором прописано регулярное выражение.

  5 - разбивка по элементам массива. Вместо FileTXT прописывается имя массива.
  Могут использоваться:
    - имена глобальных массивов GLOBALNAME см. Дополнение №23.
    - имена переменных var_... без префикса $ , созданных командой exect.
  Может использоваться 3 необязательных параметра Name!!Ext!!Start, разделённые !! :
    1) Name - имя создаваемых файлов (по умолчанию имя массива).
    2) Ext - расширение (по умолчанию txt).
    3) Start - с какого элемента начать (по умолчанию с нулевого 0).

  6 - разбивка по заданной строке (вся строка является разделителем).

  7 - разбивка по заданной строке (каждый символ строки является разделителем).

  8 - разбивка по заданной строке регулярного выражения.
  В параметре прописывается:
     • RegExp регулярное выражение.
     • ??Key - ключ из TCIMG.ini из секции [FormatUser], в котором прописано регулярное выражение.

  9 - разбивка INI файла по секциям (без добавлении имени секции в содержимое файлов).
  Может использоваться необязательный параметр:
    1 - к имени прибавляется имя секции.
Дополнительные параметры:
owrite<>Перезапись. Параметр owrite<Number>, где Number:
 Описание
  0 - не перезаписывать существующий файл, добавляется счётчик.
  1 - перезаписывать, если файл существует.
  8 - пропустить при совпадении имени объекта.
  10 - если файл существует - перезаписывать; пропускать, если подобный файл не существует по целевому пути.
  11 - если файл существует - добавлять счётчик; пропускать, если подобный файл не существует по целевому пути.
  12 - если файл существует, то к целевому файлу добавляется счётчик.
  13|Ext - если файл существует, то к целевому файлу добавляется заданное расширение Ext.
  14|Name - если файл существует, то целевой файл перемещается в заданную/создаваемую папку Name по целевому пути.
  15|StringName - если файл существует, то к имени целевого файла добавляется заданная приставка; тег :N: в StringName заменяется именем файла.

Режимы 50 - 59 сравнивают файлы по датам.
Numbers - номер или номера через запятую 0, 1, 2
    0 - время последней модификации.
    1 - время создания.
    2 - время последнего доступа.
    Если проверяются несколько дат, то для определения "нового" файла можно в конце указать "-1", будет означает, что если все даты файла новее другого, то он считается "новым" 0,1,2,-1. По умолчанию, если хотя бы одна дата новее, то он считается "новым"

  50|Numbers - если дата исходного файла новее, то целевой файл заменяется. Иначе пропускается.
  51|Numbers - если дата исходного файла старше, то целевой файл заменяется. Иначе пропускается.
  52|Numbers - если дата исходного файла новее, то к создаваемому файлу прибавляется счётчик. Иначе пропускается.
  53|Numbers - если дата исходного файла старше, то к создаваемому файлу прибавляется счётчик. Иначе пропускается.
  54|Numbers - если дата исходного файла новее, то к целевому файлу прибавляется счётчик. Иначе пропускается.
  55|Numbers - если дата исходного файла старше, то к целевому файлу прибавляется счётчик. Иначе пропускается.
  56|Numbers|Ext - если дата исходного файла новее, то к целевому файлу прибавляется заданное расширение. Иначе пропускается.
  57|Numbers|Ext - если дата исходного файла старше, то к целевому файлу прибавляется заданное расширение. Иначе пропускается.
  58|Numbers|Name - если дата исходного файла новее, то целевой файл перемещается в заданную/создаваемую папку Name по целевому пути. Иначе пропускается.
  59|Numbers|Name - если дата исходного файла старше, то целевой файл перемещается в заданную/создаваемую папку Name по целевому пути. Иначе пропускается.
  60|Numbers|StringName - если дата исходного файла новее, то к имени целевого файла добавляется заданная приставка; тег :N: в StringName заменяется именем файла. Иначе пропускается.
  61|Numbers|StringName - если дата исходного файла старше, то к имени целевого файла добавляется заданная приставка; тег :N: в StringName заменяется именем файла.. Иначе пропускается.

Режимы 20 и 21 работают не для всех команд, где подключён параметр owrite<>
Режимы работают для команд связанных с текстовыми преобразованиями.
  20|Delimeter - если файл существует, то записывать в конец файла через разделитель Delimeter (необязательный)
  21|Delimeter - если файл существует, то записывать в начало файла через разделитель Delimeter (необязательный)
Далее при существовании файла проверяются контрольные суммы 2-х файлов:

  2|x - если они не совпадают, то к создаваемому файлу прибавляется счётчик.
          если они совпадают, то файл пропускается.

  3|x - если они не совпадают, то к создаваемому файлу прибавляется счётчик.
          если они совпадают, то файл перезаписывается.

  4|x - если они не совпадают, то существующий файл перезаписывается.
          если они совпадают, то файл пропускается.

  5|x - если они не совпадают, то существующий файл перезаписывается.
          если они совпадают, то к создаваемому файлу прибавляется счётчик.

  6|x - если они не совпадают, то файл пропускается.
          если они совпадают, то существующий файл перезаписывается.

  7|x - если они не совпадают, то файл пропускается.
          если они совпадают, то к создаваемому файлу прибавляется счётчик.

  30|x - если они не совпадают, то к целевому файлу прибавляется счётчик.

  31|x|Ext - если они не совпадают, то к целевому файлу прибавляется заданное расширение Ext.
          если они совпадают, то файл пропускается.

  32|x|Name - если они не совпадают, то целевой файл перемещается в заданную/создаваемую папку Name по целевому пути.
          если они совпадают, то файл пропускается.

  33|x|StringName - если они не совпадают, то к имени целевого файла добавляется заданная приставка; тег :N: в StringName заменяется именем файла.
          если они совпадают, то файл пропускается.

  х - метод сравнения:
    1 - подсчёт контрольной суммы MD5
    2 - подсчёт контрольной суммы SHA1
    3 - подсчёт контрольной суммы CRC32
    4 - подсчёт контрольной суммы MD2
    5 - подсчёт контрольной суммы MD4
    6 - подсчёт контрольной суммы SHA256
    7 - подсчёт контрольной суммы SHA384
    8 - подсчёт контрольной суммы SHA512
    9 - подсчёт контрольной суммы MAC
DialogsДиалоги. см. Дополнение №18
  Описание
Различные параметры диалогов.
  [input] - диалог ввода информации в InputBox.
  [richinput] - диалог ввода информации в RichInputBox.
  [combo] - диалог выбора информации в ComboBox.
  [group] - диалог выбора информации в GroupBox.
  [check] - диалог выбора информации в CheckBox.
  [edits] - диалог выбора информации в EditBox.
  [sfold] - выбор каталога.
  [zfold] - выбор каталогов.
  [sopen] - выбор файла для открытия.
  [ssave] - выбор файла для сохранения.
  [sicon] - диалог просмотра и выбора значка.
  [msgbx] - окно сообщения MsgBox.
  [updwn] - диалог выбора числовой информации UpDown.
  [image] - диалог выбора изображения.
  [elect] - диалог выбора файлов и папок.
...и другие диалоги.
clpgetИз буфера обмена. Параметр clpget может использоваться совместно с другими параметрами, clpget будет заменён содержимым буфера обмена.
upd<>Обновление панели.
  Описание
Параметр upd<Number>, где Number - значение обновления панели(ей) Total Commander:
  1 - обновить активную панель.
  2 - обновить обе панели, вернуться в активную.
  3 - обновить другую панель, вернуться в активную.
  4 - обновить активную панель, перейти в другую.
  5 - обновить другую панель, остаться в другой.
  6 - обновить обе панели, остаться в другой.
  7 - не обновлять (по умолчанию, т.е. если параметр не прописан, то панели не обновляются).
<info>Получение различной информации. см. Дополнение №10.
<xinfo>Получение различной информации. см. Дополнение №10.
  Аналог параметра <info>, имеет возможность внутри параметра использовать параметр <info>
  Пример: <xinfo=o450<info=f50FilePath//>//>
namesplit<>Имя. Параметр namesplit<String> позволяет сохранять файлы с заданным именем, где String - варианты:
  Name.Ext - Name - базовое имя файла, Ext - расширение. К базовому имени прибавляется счётчик.
  **SeriesParam - позволяет получать имя файла относительно содержимого текста, где SeriesParam - серия параметров для преобразования. см. Дополнение №24 (Разделитель между параметрами ;; ).
  List - список имён файлов, возможны варианты:
    с:\List.txt - путь к файлу имён.
    $GLOBALNAME - список имён глобальной переменной.
linesp<>Вставка. Параметр linesp<LINE1!!LINE2> - позволяет в текст добавить: LINE1 - строка в начало, LINE2 - строка в конец. Разделитель !!.
При пустых значениях разделитель обязателен.
Угловые скобки заменяются соответствующими двойными фигурными.
Возможны варианты:
  • String - строка.
  • @Path - путь объекта (символ @ отбрасывается).
  • cliptext - текст из буфера обмена.
  • File - полный путь к файлу, берётся его содержимое.
  • GLOBALNAME<xN> - информация из глобальных переменных см. Дополнение №23.
Так же возможно использование параметров enum[] и string[].
string[]Дубликат. Параметр string[Count|String], позволяет размножить заданную строку String, где Count - количество раз.
enum[]Счётчик для содержимого создаваемых файлов.
  Описание
Параметр enum[Begin|Step|Count], где:
  Begin - начальное число.
  Step - шаг счётчика.
  Count - количество цифр в счётчике.
Так же поддерживается буквенный счётчик: enum[Letter|Step|Count], где:
  Letter - буква с которой начать отсчёт.
  Step - шаг счётчика.
  Count - количество букв в счётчике.

Могут применяться 2 варианта:
  1. В котором используются все три подпараметра [A|3|2] - аналог счётчика в диалоге переименования в Total Commander
  2. В котором используется только первые два [A+] или [A+|1] (к символу с которого начинать дописывается +)

Счётчик может быть как латинским, так и кириллицей, в зависимости от заданной буквы Letter
namec<>Не присваивать счётчик. Параметр namec<> позволяет не добавлять счётчик к имени при единственном создаваемом файле при разбивке.
tcg<>Вставка. Параметр tcg<NameSection> - где NameSection - имя секции в файле .tcg. В секции прописывается любой текст, а также тег "##center##" в нужном месте, вместо которого будет вставлен преобразованный текст файла см. Дополнение №31.
code<>Кодировка. Параметр code<Number>, где Number:
  0 - ANSI 1251.
  1 - UTF-16 LE 1200.
  2 - UTF-16 BE 1201.
  3 - UTF-8 с BOM.
  4 - UTF-8 без BOM.
  По умолчанию кодировка оригинального файла.
nozero<>Номер. Параметр nozero<Number> , где Number :
  0 - обычный счётчик (по умолчанию).
  1 - счётчик без начальных нулей.
  2 - счётчик без начальных нулей, первое имя без счётчика.
  3 - не добавлять счётчик.
  4 - без добавлении имени файла (к секции).

Примечания:

Аналог команды для нескольких объектов txtss

Команда имеет возможность передавать другим командам информацию через именные глобальные переменные. см. Дополнение №23

Имя переменнойОписание
GLOBALTXTSP0массив входных данных (в первой ячейке путь исходного файла или имя массива)
GLOBALTXTSPмассив выходных данных (список путей созданных файлов)

См. также:

chset, count, extra, extrf, stext, textt, textx, txtss, words, xlsxf, xlsxt

Примеры:
 Как создать кнопку?

alist=cliplist||##<info=e66::>.url slist=cliplist||##URL=<info=e70::>||^^[InternetShortcut]@CRLF txtsp=GLOBALSLIST<t>||"%p"||1!!2||namesplit<$GLOBALALIST>||nozero<3>||upd<1> ;; создать именные URL ярлыки для списка ссылок из буфера обмена

global creat="%P"||xxx.txt||clip<> txtsp=GLOBALCREAT<1>||"%p"||1!!=3||upd<1> ;; содержимое буфера обмена разрезать на 3 равные части по числу строк и создать файлы в активной панели

global creat=$f200User\||U.txt||clip<> txtsp=GLOBALCREAT<1>||$f200User\||1!!=3 ;; содержимое буфера обмена разрезать на 3 равные части с сохранением каждой части в отдельный файл \Files\User\U№.txt

global lists=%WL||##<info=f1::|1//>||^^cntr<1|1|1>~~||$$~~¤¤<info=f13:://> txtsp=GLOBALLISTS<t>||"%p"||1!!50||namesplit<list_MD5-xesh-@<info=s47>.txt> ;; создания из выделенных файлов - списка с их номером, именем и md5 суммой и разбивкой списка по 50 строк при создании

global txtsp=%P%N||"%t"||1 GLOBALTXTSP0<a> GLOBALTXTSP<a> ;; разбить текстовый файл под курсором построчно, создавая в другой панели файлы со строками и получить списки данных

global txtsp=%P%N||"%t"||6!!</p><p>||formt<63,20> stext=$GLOBALTXTSP||"%t"//0//Result.txt||delim<@CRLF{{/p}}{{p}}@CRLF!!1>||upd<3> ;; разбить текстовый файл под курсором по фразе "</p><p>", создавая в другой панели файлы с содержимым разбитых фрагментов, сортируя строки по числовому возрастанию + далее собрать файлы в один Result.txt

global txtsp=%P%N||%%TCIMG_TEMP%%||6!!#METKA#||formt<63,20> stext=$GLOBALTXTSP||"%p"//1//<info=f13GLOBALTXTSP0<1>//>||delim<@CRLF#METKA#@CRLF!!1>||upd<1> tempxx ;; сортировать в файле под курсором строки между метками "#METKA#" по числовому возрастанию

global txtsp=%WL||"%p"||1 renms=$GLOBALTXTSP||list<%WL>||**0!!txt||upd<1> ;; создать выделенным файлам именные файлы txt с содержимым полного пути файла

imgpr=1 sends=<info=f12%P%N//> txtsp=%P%N||"%t%O"||2!!1||nozero<3> renms=GLOBALTXTSP<t>||?B51!!GLOBALSENDS<1>||upd<3> ;; из файла под курсором извлечь секции в другую панель удалив префиксы (имя файла) в именах секций

imgpr=1 tempxx sends=<info=f12%P%N//> txtsp=%P%N||$f254||2!!1||nozero<3> renms=$GLOBALTXTSP||?B51!!GLOBALSENDS<1> textx=PS<$f254//1//0>||?T|d,1||formt<63>||backup<0> alist=PS<$f254//1//0>||test<1n!!^em_nik> renms=$GLOBALALIST||em_sib_cntr<1+|1|4>||[double] textt=%P%N||## slist=PS<$f254//1//0> <FOR> 1 <TO> GLOBALSLIST<0> sends=<info=f12GLOBALSLIST<:INDEX:>//> iniws=%P%N||GLOBALSENDS<1>||GLOBALSLIST<:INDEX:> <NEXT> ;; в INI файле под курсором переименовать названия секций начинающихся с em_nik на em_sib_000№ + общая сортировка секций

sends=$f212\J.txt??-1||^^=1.1@CRLF||&?=(\d+\.\d+)||&&(?m)^(.+)$!!$1.json txtsp=$f212\J.txt||C:\TestJ\||8!!=(\d+\.\d+)||namesplit<$GLOBALSENDS>||code<4>||nozero<3> ;; разбить файл по регулярному выражению с именами "меток"

sends=%P%N??1||#L1:30||formt<1,63,56,54,51> $GLOBALKENDS~$GLOBALSENDS[1] txtsp=GLOBALKENDS<t>||%%TCIMG_TEMP%%\||1!!4~7||namesplit<list.txt> ;; из файла списка под курсором, считать 30 строк, перемешать их случайным образом и создать списки файлов в папке TCIMG_TEMP, содержащие диапазоны строк со случайным выбором (от 4 до 7) в каждом файле

sends=%P%N??-8<¤>||?F1,63:C:54:C:<¤> GLOBALSENDS<a> txtsp=GLOBALSENDS||"%t"||5!!Name!!html!!1||owrite<2|1>||code<4> ;; получить в массиве два преобразования содержимого файла под курсором и создать в другой панели 2 файла Name_N.html

sends=%P%N??-8<¤>||?F1,63:C:54:C:<¤> txtsp=GLOBALSENDS||"%t"||5!!x!!x!!1||owrite<2|1>||code<4>||namesplit<**?4|##|-dell-scrypt.html#-only-zam.html|#|:NUMBER:>||nozero<3>||upd<3> ;; получить в массиве два преобразования содержимого файла под курсором и создать в другой панели 2 файла с заданными именами

sends=%P%N??-8<¤>||?Ftitle200,symdel:C:1,63:C:54:C:<¤> txtsp=GLOBALSENDS||"%t"||5!!x!!x!!2||owrite<2|1>||code<4>||namesplit<**##GLOBALSENDS<1>;;?4|$$|-dell-scrypt.html#-only-zam.html|#|:NUMBER:>||nozero<3>||upd<3> ;; получить в массиве три преобразования содержимого файла под курсором и создать в другой панели 2 файла с заданными именами

sends=%P%N??-8DualShot_2 txtsp=GLOBALSENDS||"%t"||5!!"%O"!!jpg!!1||upd<3>||code<0> ;; разбить двойное изображение JPG под курсором по тегу DualShot и сохранить их в другой панели

sends=-1??-5|=3 txtsp=GLOBALSENDS||"%p"||5!!xxx!!txt!!1||upd<1> ;; разрезать содержимое буфера обмена на 3 равные части по числу строк и записать в глобальный массив

sends=-4 txtsp=GLOBALSENDS<t>||C:\xxx||1!!10||namesplit<**##Akel_!_@.txt;;#N@!!tnum[:NUMBER:|1|5]>||nozero<3> ;; текст активного документа AkelPad разбить по 10 строк и сохранить в папку C:\xxx в файлы Akel_!_.txt с 5-м счётчиком

slist=%WL txtsp=GLOBALSLIST<t>||"%t"||1!!5||namesplit<Name.txt> ;; создать в другой панели списки выделенных объектов по 5 в каждом именами Name.txt и счётчиком

slist=%WL txtsp=GLOBALSLIST<t>||"%t"||1!!5||namesplit<Name.txt>||linesp<!!!!@CRLF{{p}}--EEE--{{/p}}@CRLF> ;; создать в другой панели списки выделенных объектов по 5 в каждом именами Name.txt и счётчиком + добавлять в каждый файл в конец <p>--EEE--</p>

slist=%WL txtsp=GLOBALSLIST<t>||"%t"||1!!5||namesplit<Name.txt>||linesp<!!@CRLF--EEE--@CRLF> ;; создать в другой панели списки выделенных объектов по 5 в каждом именами Name.txt и счётчиком + добавлять в каждый файл в конец --EEE--

slist=%WL txtsp=GLOBALSLIST<t>||"%t"||1!!5||namesplit<Name.txt>||linesp<@CRLF--BBB--@CRLF!!@CRLF--EEE--@CRLF> ;; создать в другой панели списки выделенных объектов по 5 в каждом именами Name.txt и счётчиком + добавлять в каждый файл в начало --BBB--, а в конец --EEE--

slist=%WL txtsp=GLOBALSLIST<t>||"%t"||1!!5||namesplit<Name.txt>||linesp<@CRLF--BBB--@CRLF!!> ;; создать в другой панели списки выделенных объектов по 5 в каждом именами Name.txt и счётчиком + добавлять в каждый файл в начало --BBB--

slist=%WL txtsp=GLOBALSLIST<t>||"%t"||1!!5||namesplit<Test-@<info=s47>.txt> ;; создать в другой панели списки выделенных объектов по 5 в каждом именами системного времени.txt и счётчиком

slist=%WL txtsp=GLOBALSLIST<t>||"%t"||5!!Array!!txt||upd<3> ;; разбить массив, создавая в другой панели файлы с содержимым ячеек

slist=%WL||##path<6> txtsp=GLOBALSLIST<t>||"%p"||1 renms=$GLOBALTXTSP||list<%WL>||**0!!||upd<1> ;; создать выделенным файлам именные файлы без расширения с содержимым именем файла

slist=%WL||##path<6> txtsp=GLOBALSLIST<t>||"%p"||1 renms=$GLOBALTXTSP||list<%WL>||**0!!txt||upd<1> ;; создать выделенным файлам именные файлы txt с содержимым именем файла

slist=cliplist||##URL=<info=e70::>||^^[InternetShortcut]@CRLF txtsp=GLOBALSLIST<t>||"%p"||1!!2||namesplit<**?F6,sps333;;$$.url>||nozero<3>||upd<1> ;; создать именные URL ярлыки для списка ссылок из буфера обмена

slist=cliplist||##URL=<info=e70::>||^^[InternetShortcut]@CRLF txtsp=GLOBALSLIST<t>||"%p"||1!!2||namesplit<**?F6,sps333-1>||nozero<3>||upd<1> ;; создать в активной панели именные URL ярлыки для списка ссылок из буфера обмена в создаваемых именных папках

tempxx itray=3||4 xclip=1 asave=GLOBALXCLIP||$f254ClipAll.txt|1 txtsp=$f254ClipAll.txt||$f254Button||1!!9 slist=PS<$f254Button!!1!!0> <FOR> 1 <TO> GLOBALSLIST<0> barbt=1||-1||butfrom<GLOBALSLIST<:INDEX:>> <NEXT> ;; запустить команду слежения за буфером обмена, скопировать нужные кнопки TC, при повторном вызове команды завершить слежение и создать скопированные кнопки на активной панели инструментов

txtsp=%P%N||"%p"||1!!5||namesplit<test.txt>||linesp<@CRLF---enum[3|3|1]---@CRLF@CRLF!!>||upd<1> ;; разбить текстовый файл под курсором по 5 строк, создавая в активной панели файлы со строками + добавлять в каждый файл в начало --счётчик--

txtsp=%P%N||"%p"||1!!5||namesplit<test.txt>||linesp<@CRLF--enum[3|3|1]--enum[5|5|1]--@CRLF@CRLF!!>||upd<1> ;; разбить текстовый файл под курсором по 5 строк, создавая в активной панели файлы со строками + добавлять в каждый файл в начало --счётчики--

txtsp=%P%N||"%p"||1!!5||namesplit<test.txt>||linesp<@CRLF---enum[A|1|2]---@CRLF@CRLF!!>||upd<1> ;; разбить текстовый файл под курсором по 5 строк, создавая в текущей панели файлы со строками + добавлять в каждый файл в начало --буквенный счётчик №2-- (минимальное количество цифр в счётчике 2)

txtsp=%P%N||"%p"||1!!5||namesplit<test.txt>||linesp<@CRLF---enum[A+]---@CRLF@CRLF!!>||upd<1> ;; разбить текстовый файл под курсором по 5 строк, создавая в активной панели файлы со строками + добавлять в каждый файл в начало --буквенный счётчик №1--

txtsp=%P%N||"%p"||1!!5||namesplit<test.txt>||linesp<@CRLFstring[10|=]enum[3|3|1]string[10|=]@CRLF@CRLF!!>||upd<1> ;; разбить текстовый файл под курсором по 5 строк, создавая в активной панели файлы со строками + добавлять в каждый файл в начало счётчик обрамив десятью символами "="

txtsp=%P%N||"%t"||1!![combo=BOX17]||upd<3> ;; разбить файл под курсором в другую панель, с выбором в диалоге количества строк

txtsp=%P%N||"%t"||1!!1!!6!!20 ;; разбить текстовый файл под курсором построчно начиная с 6-й и заканчивая 20-й, создавая в другой панели файлы со строками

txtsp=%P%N||"%t"||1!!2!!6 ;; разбить текстовый файл под курсором по 2 строки начиная с 6-й, создавая в другой панели файлы со строками

txtsp=%P%N||"%t"||1!!4~7||namesplit<list.txt>||upd<3> ;; разбить текстовый файл под курсором построчно, создавая в другой панели файлы со случайным количеством строк (диапазон от 4 до 7 строк)

txtsp=%P%N||"%t"||1!!5 ;; разбить текстовый файл под курсором по 5 строк, создавая в другой панели файлы со строками

txtsp=%P%N||"%t"||1 ;; разбить текстовый файл под курсором построчно, создавая в другой панели файлы со строками

txtsp=%P%N||"%t"||1||nozero<1>||upd<3> ;; разбить текстовый файл под курсором построчно, создавая в другой панели файлы со строками, счётчик без ведущего нуля

txtsp=%P%N||"%t"||1||nozero<2>||upd<3> ;; разбить текстовый файл под курсором построчно, создавая в другой панели файлы со строками, счётчик без ведущего нуля, первое имя без приставки и без счётчика

txtsp=%P%N||"%t"||1||progres<>||upd<3> ;; разбить текстовый файл под курсором построчно, создавая в другой панели файлы со строками, с прогресс баром + обновить другую панель после разбивки

txtsp=%P%N||"%t"||2!!1 ;; разбить -INI файл под курсором по секциям, создавая в другой панели именные файлы с секциями

txtsp=%P%N||"%t"||2 ;; разбить -INI файл под курсором по секциям, создавая в другой панели файлы с секциями

txtsp=%P%N||"%t"||3!!1 ;; разбить -INI файл под курсором по секциям (сохраняя комментарии для секций), создавая в другой панели именные файлы с секциями

txtsp=%P%N||"%t"||4!!(?m)((?:[^\r\n]+(?:\r\n|$)+){1,5})||namesplit<Name.html>||tcg<HTML1>||code<4>||upd<3> ;; разбить текстовый файл под курсором по пять строк, добавив их в шаблон HTML1 и сохранить в другую панель с именами Name...html в кодировке UTF-8

txtsp=%P%N||"%t"||4!!(?m)((?:[^\r\n]+(?:\r\n|$)+){1,5})||namesplit<Name.html>||tcg<HTML1>||upd<3> ;; разбить текстовый файл под курсором по пять строк, добавив их в шаблон HTML1 и сохранить в другую панель с именами Name...html

txtsp=%P%N||"%t"||4!!(?ms)@font-face(?:[\s]+)?\{[^\{]+\} ;; разбить -CSS файл под курсором по фрагментам @font-face, создавая в другой панели файлы с фрагментами

txtsp=%P%N||"%t"||4!!??aray_css1 ;; разбить файл под курсором по фрагментам, используя регулярное выражение для поиска прописанного в секции [FormatUser] в ключе aray_css1 , создавая в другой панели файлы с фрагментами

txtsp=%P%N||"%t"||6!!</p><p>||formt<63,20>||upd<3> ;; разбить текстовый файл под курсором по фразе "</p><p>", создавая в другой панели файлы с содержимым разбитых фрагментов, сортируя строки по числовому возрастанию

txtsp=%P%N||"%t"||7!!;-,||upd<3> ;; разбить текстовый файл под курсором по ";", "-", "," создавая в другой панели файлы с содержимым разбитых фрагментов

txtsp=%P%N||"%t"||8!!#M#|@N@||upd<3> ;; разбить текстовый файл под курсором по меткам "#M#", "@N@" , создавая в другой панели файлы с содержимым разбитых фрагментов

txtsp=%P%N||"%t"||8!!#METKA[\d]*#||upd<3> ;; разбить текстовый файл под курсором по фразам "#METKA1#", "#METKA2#" ... создавая в другой панели файлы с содержимым разбитых фрагментов

txtsp=%P%N||"%t"||9!!1||owrite<20|@CRLF>||nozero<4>||progres<>||upd<3> ;; разбить -INI файл под курсором по секциям, создавая в другой панели именные файлы с именами секций (без названий секций в содержимом файлов), если файл существует, то записывать в конец файла через разделитель

txtsp=%P%N||"%t"||9!!1||owrite<20|@CRLF>||progres<>||upd<3> ;; разбить -INI файл под курсором по секциям, создавая в другой панели именные файлы с секциями (без названий секций в содержимом файлов), если файл существует, то записывать в конец файла через разделитель

txtsp=%P%N||"%t"||9!!1||owrite<20|@CRLF>||progres<>||upd<3> ;; разбить -INI файл под курсором по секциям, создавая в другой панели именные файлы с секциями (без названий секций в содержимом файлов), если файл существует, то записывать в начало файла через разделитель

txtsp=%P%N||"%t"||9!!1||owrite<20>||progres<>||upd<3> ;; разбить -INI файл под курсором по секциям, создавая в другой панели именные файлы с секциями (без названий секций в содержимом файлов), если файл существует, то записывать в конец файла

txtsp=%P%N||"%t"||9!!1||owrite<21>||progres<>||upd<3> ;; разбить -INI файл под курсором по секциям, создавая в другой панели именные файлы с секциями (без названий секций в содержимом файлов), если файл существует, то записывать в начало файла

txtsp=%P%N||"%t"||9!!1||progres<>||upd<3> ;; разбить -INI файл под курсором по секциям, создавая в другой панели именные файлы с секциями (без названий секций в содержимом файлов)

txtsp=%P%N||"%t"||9||progres<>||upd<3> ;; разбить -INI файл под курсором по секциям, создавая в другой панели файлы с секциями (без названий секций в содержимом файлов)

txtsp=%P%N||"%t"<info=f1%P%N//>||4!!... ;; разбить текстовых файл под курсором по три символа, создавая в другой панели файлы

txtsp=%P%N||"%t%O"||1||progres<>||upd<3> ;; разбить текстовый файл под курсором построчно, создавая в другой панели в именной папке файлы со строками, с прогресс баром + обновить другую панель после разбивки

txtsp=%P%N||"%t%O"||2!!1 ;; разбить -INI файл под курсором по секциям, создавая в другой панели именные файлы с секциями в именной папке

txtsp=%P%N||"%t%O"||2!!1||progres<>||upd<3> ;; разбить -INI файл под курсором по секциям, создавая в другой панели именные файлы с секциями в именной папке, с прогресс баром + обновить другую панель после разбивки


© Аверин Андрей для Total Commander Image  Averin-And@yandex.ru