Описание команды


downl

Закачка из списка ссылок.

downl=Path||ListLINK, ||owrite<>, ||metod<>, ||tip<>, ||pause<>, ||sagent<>, ||sproxy<>, ||progres<>, ||cntlr<>, ||Dialogs, ||[tc], ||convert<>, ||stopd<>, ||uformat<>, ||limit<>, ||test<>, ||<info>, ||<xinfo>, ||upd<>

Параметры:

1-й обязательный параметр.
PathПуть. Параметр Path//Mode , где:
  Path - путь, куда будут закачаны файлы.
    @ - используется при параметре listu<> - путь будет взят, относительно пути активного списка.
  Mode:
    1 - добавлять счётчик при совпадении имён.
    2 - заменять при совпадении имён.
    4 - пропускать при существовании объекта.
    9 - проверка создания файла с помощью параметра owrite<>
2-й обязательный параметр.
ListLINKСписок ссылок.
  • Path - путь к списку ссылок c:\List.txt.
  • cliplist - список ссылок из буфера обмена.
  • GLOBALNAME - данные, переданные глобальными переменными. см. Дополнение №23.
  • listu<List> : List - список путей файлов, в которых находятся ссылки.
    (т.е. будет произведена закачка по нескольким спискам).
Дополнительные параметры:
owrite<>Режим действий для файлов. Параметр owrite<Number>, где Number:
 Описание
  0 - не перезаписывать существующий файл, добавляется счётчик.
  1 - перезаписывать, если файл существует.
  8 - пропустить при совпадении имени объекта.
  10 - если файл существует - перезаписывать; пропускать, если подобный файл не существует по целевому пути.
  11 - если файл существует - добавлять счётчик; пропускать, если подобный файл не существует по целевому пути.
  12 - если файл существует, то к целевому файлу добавляется счётчик.
  13|Ext - если файл существует, то к целевому файлу добавляется заданное расширение Ext.
  14|Name - если файл существует, то целевой файл перемещается в заданную/создаваемую папку Name по целевому пути.
  15|StringName - если файл существует, то к имени целевого файла добавляется заданная приставка; тег :N: в StringName заменяется именем файла.

Режимы 50 - 59 сравнивают файлы по датам.
Numbers - номер или номера через запятую 0, 1, 2
    0 - время последней модификации.
    1 - время создания.
    2 - время последнего доступа.
    Если проверяются несколько дат, то для определения "нового" файла можно в конце указать "-1", будет означает, что если все даты файла новее другого, то он считается "новым" 0,1,2,-1. По умолчанию, если хотя бы одна дата новее, то он считается "новым"

  50|Numbers - если дата исходного файла новее, то целевой файл заменяется. Иначе пропускается.
  51|Numbers - если дата исходного файла старше, то целевой файл заменяется. Иначе пропускается.
  52|Numbers - если дата исходного файла новее, то к создаваемому файлу прибавляется счётчик. Иначе пропускается.
  53|Numbers - если дата исходного файла старше, то к создаваемому файлу прибавляется счётчик. Иначе пропускается.
  54|Numbers - если дата исходного файла новее, то к целевому файлу прибавляется счётчик. Иначе пропускается.
  55|Numbers - если дата исходного файла старше, то к целевому файлу прибавляется счётчик. Иначе пропускается.
  56|Numbers|Ext - если дата исходного файла новее, то к целевому файлу прибавляется заданное расширение. Иначе пропускается.
  57|Numbers|Ext - если дата исходного файла старше, то к целевому файлу прибавляется заданное расширение. Иначе пропускается.
  58|Numbers|Name - если дата исходного файла новее, то целевой файл перемещается в заданную/создаваемую папку Name по целевому пути. Иначе пропускается.
  59|Numbers|Name - если дата исходного файла старше, то целевой файл перемещается в заданную/создаваемую папку Name по целевому пути. Иначе пропускается.
  60|Numbers|StringName - если дата исходного файла новее, то к имени целевого файла добавляется заданная приставка; тег :N: в StringName заменяется именем файла. Иначе пропускается.
  61|Numbers|StringName - если дата исходного файла старше, то к имени целевого файла добавляется заданная приставка; тег :N: в StringName заменяется именем файла.. Иначе пропускается.

Режимы 20 и 21 работают не для всех команд, где подключён параметр owrite<>
Режимы работают для команд связанных с текстовыми преобразованиями.
  20|Delimeter - если файл существует, то записывать в конец файла через разделитель Delimeter (необязательный)
  21|Delimeter - если файл существует, то записывать в начало файла через разделитель Delimeter (необязательный)
Далее при существовании файла проверяются контрольные суммы 2-х файлов:

  2|x - если они не совпадают, то к создаваемому файлу прибавляется счётчик.
          если они совпадают, то файл пропускается.

  3|x - если они не совпадают, то к создаваемому файлу прибавляется счётчик.
          если они совпадают, то файл перезаписывается.

  4|x - если они не совпадают, то существующий файл перезаписывается.
          если они совпадают, то файл пропускается.

  5|x - если они не совпадают, то существующий файл перезаписывается.
          если они совпадают, то к создаваемому файлу прибавляется счётчик.

  6|x - если они не совпадают, то файл пропускается.
          если они совпадают, то существующий файл перезаписывается.

  7|x - если они не совпадают, то файл пропускается.
          если они совпадают, то к создаваемому файлу прибавляется счётчик.

  30|x - если они не совпадают, то к целевому файлу прибавляется счётчик.

  31|x|Ext - если они не совпадают, то к целевому файлу прибавляется заданное расширение Ext.
          если они совпадают, то файл пропускается.

  32|x|Name - если они не совпадают, то целевой файл перемещается в заданную/создаваемую папку Name по целевому пути.
          если они совпадают, то файл пропускается.

  33|x|StringName - если они не совпадают, то к имени целевого файла добавляется заданная приставка; тег :N: в StringName заменяется именем файла.
          если они совпадают, то файл пропускается.

  х - метод сравнения:
    1 - подсчёт контрольной суммы MD5
    2 - подсчёт контрольной суммы SHA1
    3 - подсчёт контрольной суммы CRC32
    4 - подсчёт контрольной суммы MD2
    5 - подсчёт контрольной суммы MD4
    6 - подсчёт контрольной суммы SHA256
    7 - подсчёт контрольной суммы SHA384
    8 - подсчёт контрольной суммы SHA512
    9 - подсчёт контрольной суммы MAC
metod<>Метод закачивания. Параметр metod<Number>, где Number:
  0 - закачивание внутренними средствами Autoit (по умолчанию).
  1 - закачивание с помощью объекта MSXML2.XMLHTTP.
  2 - закачивание внутренними средствами, если нет результата, то с помощью объекта MSXML2.XMLHTTP.
  3 - закачивание с помощью объекта MSXML2.XMLHTTP, если нет результата, то внутренними средствами.
tip<>Скачивание файлов в папки по типу. Параметр tip<Section(!!Number)>, где:
Section - секция, где прописываются Ключи (папки) и значения (маска-шаблон типов):
Пример записи:

Arhives=*.7z|*.7zip|*.rar
Musics=*.mp3|*.wav|*.wma
Scripts=*.bat|*.cmd|*.vbs|*.js

Дополнительные настройки в TCIMG.ini в ключе FolderExtensions.
При использовании своих языковых папок прописывается 2-й подпараметр через !! - Number - номер ключа FolderLang (1 - FolderLang1; 2 - FolderLang2... N - FolderLangN) в TCIMG_.lng, в ключе FolderExtZiro прописывается имя папки для расширений, не входящих в шаблоны.
pause<>Пауза между закачками. Параметр pause<Seconds(-Range)>, где Seconds пауза в секундах.
Для использования диапазона прописывается необязательный параметр через -
При этом Section - минимальная, а Range максимальная пауза, а диапазон является случайным.
sagent<>Установить User-Agent.
  Описание
Параметр sagent<Key> устанавливает строку User-Agent (идентификатор клиентской программы) отправляемую при запросах, где:
  Key - имя ключа из TCIMG.ini из секции [HttpSetUserAgent] в котором прописана строка User-Agent.
sagent<@Key|Count> позволяет менять случайным образом User-Agent'a, где:
  Key - имя ключа в котором прописаны строки User-Agent'ов через разделитель ||
  Count - число ссылок, через которое меняется User-Agent
sagent<#Key1|Count1,Key2|Count2,...,KeyN|CountN> позволяет последовательно менять User-Agent'a, где:
  Key1|Count1 - ключ Key1 в котором прописана строка User-Agent'a устанавливается на заданное число Count1 раз,
  затем данные берутся из Key2|Count2, ... , KeyN|CountN и далее по кругу.
sproxy<>Установить интернет прокси.
  Описание
Параметр sproxy<Flag|Mode|Proxy:Port|UserName|Password> позволяет установить интернет прокси, чтобы использовать для доступа по FTP или по HTTP, где:
  Flag:
    0 - устанавливает интернет прокси для доступа по FTP
    1 - устанавливает интернет прокси для доступа по HTTP
  Mode - используемые режимы прокси:
    0 - использует текущие настройки Internet Explorer для прокси (по умолчанию).
    1 - не использует прокси (прямой доступ).
    2 - использует указанный прокси.
  Proxy:Port
    [необязательный] адрес и порт прокси для использования. Смотрите примечания ниже.
  UserName
    [необязательный] имя пользователя для прокси, если потребуется.
  Password
    [необязательный] пароль для прокси, если потребуется.
sproxy<@Flag|Mode|ListProxy*Count> позволяет случайным образом менять прокси.
sproxy<#Flag|Mode|ListProxy*Count> позволяет последовательно по кругу менять прокси.

  Count - [необязательный] число ссылок, через которое меняется прокси (по умолчанию 1).
  ListProxy - список прокси, путь к файлу списка с:\proxy.txt
     список может быть передан через глобальные переменные $GLOBALNAME см. Дополнение №23
     в каждой строке списка может быть прописано:

Пример записи:

Proxy
Proxy:Port
Proxy:Port,UserName,Password
Proxy:Port|UserName|Password

127.0.0.1
127.0.0.1:9090
127.0.0.1:9050,login1,Qh23qw
127.0.0.1:9080|login2|8t9efgdf

Примечания:

  Для работы этого параметра должен быть установлен Internet Explorer версии 3 или выше.
  Поддерживаются только CERN прокси-сервера.
  Как правило прокси-серверы состоят из веб-адреса и номера порта.
  Большинство провайдеров используют номер порта 8080.
  Если ваш прокси-сервер www.proxy.com и порт 8080, то вы должны использовать это, чтобы установить прокси:
  www.proxy.com:8080
  Большинство прокси-серверов не требуют имя пользователя и пароль.
  При использовании режима Mode=0 можно указать имя пользователя и пароль и они будут использоваться с конфигурацией прокси Internet Explorer.
progres<>Прогресс бар. Параметр progres<> - если указан, то при операции будет запущен прогресс бар.
Учитывается ключ MsBoxAtTheCompletion в TCIMG.ini в секции [Setting].
cntlr<>Счётчик. При совпадении имён:
  0 - счётчик слева.
  1 - счётчик справа (по умолчанию).
DialogsДиалоги. см. Дополнение №18
  Описание
Различные параметры диалогов.
  [input] - диалог ввода информации в InputBox.
  [richinput] - диалог ввода информации в RichInputBox.
  [combo] - диалог выбора информации в ComboBox.
  [group] - диалог выбора информации в GroupBox.
  [check] - диалог выбора информации в CheckBox.
  [edits] - диалог выбора информации в EditBox.
  [sfold] - выбор каталога.
  [zfold] - выбор каталогов.
  [sopen] - выбор файла для открытия.
  [ssave] - выбор файла для сохранения.
  [sicon] - диалог просмотра и выбора значка.
  [msgbx] - окно сообщения MsgBox.
  [updwn] - диалог выбора числовой информации UpDown.
  [image] - диалог выбора изображения.
  [elect] - диалог выбора файлов и папок.
...и другие диалоги.
[tc]Расширенный аналог параметров Total Commander. см. Дополнение №12.
convert<>Преобразование ссылки. Параметр convert<SeriesParam> позволяет преобразовать ссылку для получения из неё имени для файла скачивания, где SeriesParam - серия параметров для преобразования. см. Дополнение №24 (Разделитель между параметрами ;; ).
Внутри параметра можно использовать подпараметр <listx=List> , где List - это список имён для создаваемых файлов.
Подпараметр позволяет вставить своё имя для каждой ссылки, возможны варианты List:
    • Path - путь списка имён.
    • GLOBALNAME - данные, переданные глобальными переменными. см. Дополнение №23.
Важно! Количество имён в списке должно совпадать или быть больше количества входящих в команду ссылок.
stopd<>Остановка скачивания. Параметр stopd<Number>, где Number:
  0 - не останавливать скачивание (по умолчанию).
  N - остановить скачивание через N подряд незакаченных ссылок.
 -N - остановить скачивание через N любых незакаченных ссылок.
uformat<>Преобразование ссылки. Параметр uformat<Number>, где Number:
  1 - обрабатывать имя ссылки заменами из ключа ReplaceLink в секции [Setting] в TCIMG.ini (по умолчанию).
  0 - не обрабатывать.
limit<>Ограничение по размеру файла. Параметр limit<Flag|Number|Size1|Size2> позволяет скачивать/не скачивать относительно заданного размера, где:
  Flag:
    0 - получить размер файла из кэша, если это возможно (по умолчанию).
    1 - принудительно перезагрузить с удалённого сайта.
    2 - игнорировать все SSL ошибки (при использовании соединения HTTPS).
  Number
    0 - меньше заданного размера Size1.
    1 - больше заданного размера Size1.
    2 - равно заданному размеру Size1.
    3 - диапазон размеров (от Size1 до Size2).
  Size1 и Size2 - размер, состоит из числа и символа (примеры: 10K, 5M):
    B - байты.
    K - килобайты.
    M - мегабайты.
    G - гигабайты.
Не все сервера могут правильно выдавать размеры файлов.
test<>Проверка прохождения объекта под определённые условия. см. Дополнение №16.
<info>Получение различной информации. см. Дополнение №10.
<xinfo>Получение различной информации. см. Дополнение №10.
  Аналог параметра <info>, имеет возможность внутри параметра использовать параметр <info>
  Пример: <xinfo=o450<info=f50FilePath//>//>
upd<>Обновление панели.
  Описание
Параметр upd<Number>, где Number - значение обновления панели(ей) Total Commander:
  1 - обновить активную панель.
  2 - обновить обе панели, вернуться в активную.
  3 - обновить другую панель, вернуться в активную.
  4 - обновить активную панель, перейти в другую.
  5 - обновить другую панель, остаться в другой.
  6 - обновить обе панели, остаться в другой.
  7 - не обновлять (по умолчанию, т.е. если параметр не прописан, то панели не обновляются).

Примечания:

Там, где необходимо указывать путь можно использовать сокращения для специальных папок и файлов $f01 ... см. Дополнение №8.

В параметрах команды может использоваться:
  • GLOBALNAME - информация, получаемая из других команд через глобальные переменные см. Дополнение №23

Команда имеет возможность передавать другим командам информацию через именные глобальные переменные. см. Дополнение №23

Имя переменнойОписание
GLOBALDOWNL0массив входных данных (список исходных ссылок для закачивания)
GLOBALDOWNLмассив выходных данных (список путей файлов, которые закачались и ссылок, которые не закачались)
GLOBALDOWNL1массив успешных закачек (список путей файлов, которые закачались)
GLOBALDOWNL2массив неуспешных закачек (список ссылок, которые не закачались)
GLOBALDOWNL3массив успешных закачек (список ссылок, которые закачались)

См. также:

brwsr, downh, intcn, picup, picus, upldf, uplds, urlra, urlrf, urlsv, urlxt, websc, webss

Примеры:
 Как создать кнопку?

<TRAY=~~WIN+V~~Загрузить~~фото~~и~~видео~~с~~ссылки~~instagram@CRLF~~ESC~~-~~выход> <PRESS=56,5B> imgpr=1 sends=-1||formt<insta0> sends=#GLOBALSENDS<1>!!-1||\/!!/||formt<insta4> downl=%%COMMANDER_PATH%%\Downloads\INSTA\//2||$GLOBALSENDS||progres<> <PRESS=1B> :EXIT: ;; при WIN+V происходит загрузка в заданную папку INSTA больших фотографий n.JPG и видео n.MP4 ссылки с instagram из буфера обмена, по ESC выход из процесса

bends=-1??-1 hends=#GLOBALBENDS<1>\\4??-1||?Fimg7 slist=$GLOBALHENDS||?B5!!GLOBALBENDS<1> downl="%p"<info=n3|Line1|8>\//1||$GLOBALSLIST||progres<> ;; из содержимого ссылки из буфера обмена получить JPG изображения в тегах "href" и закачать в активную панель в создаваемую папку со случайным именем

bufsr=##http<clpget>||formt<6,1!!(.*\.mp4[^\r\n]*)> downl="%p"//2||cliplist ;; закачать все файлы .mp4 в активную панель со страницы - адрес страницы в буфере обмена

bufsr=##http<clpget>||formt<6,1!!(.*\.png[^\r\n]*)> downl="%p"//2||cliplist ;; закачать все файлы .png в активную панель со страницы - адрес страницы в буфере обмена

bufsr=##http<clpget>||formt<6,1!!(.*\.png|.*\.jpg|.*\.gif|.*\.jepg[^\r\n]*)> downl="%p"//2||cliplist||tip<Extensions!!2> ;; с интернет страницы, адрес которой из буфера получить список всех адресов изображений gif, png, jpg и скачать в активную панель

bufsr=##http<clpget>||formt<6,1!!(.*\.png|.*\.jpg|.*\.gif|.*\.jepg[^\r\n]*)> downl="%p"//2||cliplist||tip<Extensions!!2>||progres<> ;; с интернет страницы, адрес которой из буфера получить список всех адресов изображений gif, png, jpg и скачать в активную панель с прогресс баром

bufsr=##http<clpget>||formt<6> downl="%p"//0||cliplist||tip<Extensions!!2>||progres<> pause=500 renms=FOLDC<"%p"Different//1//0//:zeroext:>||extplus<> ;; закачать все ссылки со страницы, в создаваемые папки , согласно шаблону 2 и переименовать (английские имена в шаблонах) все файлы без расширения, в расширения известных типов.

bufsr=##http<clpget>||formt<6> downl="%p"//2||cliplist ;; закачать все ссылки в активную панель со страницы - адрес страницы в буфер обмена

bufsr=##http<http://www.yandex.ru>||formt<6> downl="%p"//2||cliplist ;; закачать в активную панель все ссылки со страницы http://www.yandex.ru

bufsr=^^||formt<1,lin36,lin37> downl="%p"//1||cliplist||pause<1>||progres<>||upd<1> ;; закачать из списка URL адресов в буфере (например http://rambler.ru/ или http://rambler.ru) иконки с сайтов (если такие имеются) в активную панель

downl="%p"//1||C:\link.txt||sagent<#W1|5,W8|3>||progres<1>||upd<1> ;; закачать в активную панель ссылки из файла C:\link.txt, последовательно менять User-Agent'a из ключей прописанных в [HttpSetUserAgent]: 5 раз подряд UserAgent из ключа W1 , потом 3 раз UserAgent W8, а затем по кругу

downl="%p"//1||C:\link.txt||sagent<@WW|2>||progres<1>||upd<1> ;; закачать в активную панель ссылки из файла C:\link.txt, через каждые 2 ссылки менять случайным образом User-Agent'a, из строк прописанных [HttpSetUserAgent] в ключе WW

downl="%p"//1||C:\link.txt||sproxy<#1|2|C:\proxy.txt*8>||progres<1>||upd<1> ;; закачать в активную панель ссылки из файла C:\link.txt, через каждые 8 ссылок последовательно по кругу менять прокси из списка C:\proxy.txt

downl="%p"//1||C:\link.txt||sproxy<@1|2|C:\proxy.txt*8>||progres<1>||upd<1> ;; закачать в активную панель ссылки из файла C:\link.txt, через каждые 8 ссылок менять случайным образом прокси из списка C:\proxy.txt

downl="%p"//1||cliplist ;; скачивание списка ссылок из буфера обмена в текущую панель, добавлять счётчик при совпадении имён

downl="%P"//1||cliplist||convert<##@@e67::;;$$@@e73::;;?F63;;/!!\>||uformat<0> ;; скачивание списка ссылок из буфера обмена в текущую панель, в именные создаваемые папки из части url

downl="%P"//1||cliplist||convert<##<listx=C:\Name.txt>>||uformat<0> ;; скачивание списка ссылок из буфера обмена в текущую панель, в именные файлы из списка C:\Name.txt

downl="%p"//1||cliplist||pause<1-5> ;; скачивание списка ссылок из буфера обмена в текущую панель, добавлять счётчик при совпадении имён, каждая следующая закачка происходит со случайной задержкой от 1 до 5 секунд

downl="%p"//1||cliplist||pause<1-5>||progres<>||metod<1>||upd<1> ;; скачивание списка ссылок из буфера обмена в текущую панель, добавлять счётчик при совпадении имён, каждая следующая закачка происходит со случайной задержкой от 1 до 5 секунд (используется объект MSXML2.XMLHTTP)

downl="%p"//1||cliplist||pause<1-5>||progres<>||metod<2>||upd<1> ;; скачивание списка ссылок из буфера обмена в текущую панель, добавлять счётчик при совпадении имён, каждая следующая закачка происходит со случайной задержкой от 1 до 5 секунд (используется объект MSXML2.XMLHTTP, если нет результата, то скачивание внутренними средствами)

downl="%p"//1||cliplist||pause<1-5>||progres<>||metod<3>||upd<1> ;; скачивание списка ссылок из буфера обмена в текущую панель, добавлять счётчик при совпадении имён, каждая следующая закачка происходит со случайной задержкой от 1 до 5 секунд (скачивание внутренними средствами, если нет результата, то используется объект MSXML2.XMLHTTP)

downl="%p"//2||%T%M ;; скачивание из файл-списка ссылок другой панели в текущую панель, заменять при совпадении имён

downl="%p"//2||cliplist ;; скачивание списка ссылок из буфера обмена в текущую панель, заменять при совпадении имён

downl="%p"//2||cliplist||limit<0|0|10K>||upd<1> ;; скачивание списка ссылок из буфера обмена в текущую панель, заменять при совпадении имён, закачиваются файлы, размер которых менее 10 килобайт

downl="%p"//2||cliplist||limit<0|1|30K>||upd<1> ;; скачивание списка ссылок из буфера обмена в текущую панель, заменять при совпадении имён, закачиваются файлы, размер которых более 30 килобайт

downl="%p"//2||cliplist||limit<0|2|50K>||upd<1> ;; скачивание списка ссылок из буфера обмена в текущую панель, заменять при совпадении имён, закачиваются файлы, размер которых равен 50 килобайт

downl="%p"//2||cliplist||pause<1-5> start=RAR||-IBCK||e||"%P[path=clpget|6|0|4]"||"%T[path=clpget|4|0|4]\"||&&wait||upd<2> beepss ;; скачать архив по ссылке из буфера в активную панель и распаковать в другую в именную папку с помощью Winrar в фоне

downl="%p"//2||cliplist||pause<1-5>||upd<1> beepss ;; скачать список ссылок из буфера в активную панель + издать звук при окончании, заменять при совпадении имён

downl="%p"//2||cliplist||pause<1-5>||upd<1> infbx=Закачка||Закачка~~завершена||1||200||50 ;; скачать список ссылок из буфера в активную панель +оповестить при окончании, заменять при совпадении имён

downl="%p"//2||cliplist||pause<5> ;; скачивание списка ссылок из буфера обмена в текущую панель, пауза между загрузками 5 секунд, заменять при совпадении имён

downl="%p"//2||cliplist||stopd<3>||progres<>||upd<1> ;; скачивание списка ссылок из буфера обмена в текущую панель, заменять при совпадении имён, прерывание скачивания, если не закачаются 3 ссылки подряд

downl="%p"//2||cliplist||stopd<-3>||progres<>||upd<1> ;; скачивание списка ссылок из буфера обмена в текущую панель, заменять при совпадении имён, прерывание скачивания, если не закачаются любые 3 ссылки

downl="%p"//2||cliplist||tip<Extensions> ;; скачивание списка ссылок из буфера обмена в текущую панель в создаваемые папки, соответствующие расширению, заменять при совпадении имён

downl="%p"//2||cliplist||upd<1> ;; скачивание списка ссылок из буфера обмена в текущую панель и обновить, заменять при совпадении имён

downl="%p"//9||cliplist||owrite<2|1>||upd<1> ;; скачивание списка ссылок из буфера обмена в текущую панель с условиями при существовании файла: если контрольные суммы не совпадают, то прибавить счётчик, если совпадают, то не создавать

downl="%p"//9||cliplist||owrite<3|1>||upd<1> ;; скачивание списка ссылок из буфера обмена в текущую панель с условиями при существовании файла: если контрольные суммы не совпадают, то прибавить счётчик, если совпадают, то перезаписать

downl="%p"//9||cliplist||owrite<4|1>||upd<1> ;; скачивание списка ссылок из буфера обмена в текущую панель с условиями при существовании файла: если контрольные суммы не совпадают, то перезаписать, если совпадают, то пропустить

downl="%p"//9||cliplist||owrite<5|1>||upd<1> ;; скачивание списка ссылок из буфера обмена в текущую панель с условиями при существовании файла: если контрольные суммы не совпадают, то перезаписать, если совпадают, то прибавить счётчик

downl="%p"//9||cliplist||owrite<6|1>||upd<1> ;; скачивание списка ссылок из буфера обмена в текущую панель с условиями при существовании файла: если контрольные суммы не совпадают, то пропустить, если совпадают, то перезаписать

downl="%p"//9||cliplist||owrite<7|1>||upd<1> ;; скачивание списка ссылок из буфера обмена в текущую панель с условиями при существовании файла: если контрольные суммы не совпадают, то пропустить, если совпадают, то прибавить счётчик

downl="%t"//2||%P%N ;; скачивание из файл-списка ссылок под курсором в другую панель, заменять при совпадении имён

downl=%%COMMANDER_PATH%%\Downloads\<info=l1c:\Path.txt>\//9||cliplist ;; скачивание списка ссылок из буфера обмена в папку Downloads в папку первой строки файла c:\Path.txt

downl=@//9||listu<C:\ListListURL.txt>||pause<1-2>||owrite<2|1>||progres<> ;; закачать все ссылки из списка C:\ListListURL.txt, в котором находятся пути файлов со списками URL; закачать в папку, где находятся файлы со списками

downl=C:\Img\//1||C:\Links.txt||progres<> imgcn=$GLOBALDOWNL1||x//1||test<NOT//1m!!400>||resize<1,400>||quality<90> renms=$GLOBALDOWNL1||$$_<info=i3:://>||upd<1> ;; скачать изображения по ссылкам из списка C:\Links.txt в папку C:\Img\ с последующим изменениям размеров изображениям (не имеющим ширину 400px) ширину на 400px пропорционально

exect=$var_put=##@[tc=AP] sends=-1??-1||formt<54,63> urlra=$GLOBALSENDS|4||$var_put::!!0!!(.+\\)(\w+\:/+)([^/]+).*!!$1$3\\vid-link.txt||?Fserch79,6,1||pause<1-2>||owrite<1>||progres<> GLOBALURLRA1<a> downl=@//9||listu<$GLOBALURLRA1>||pause<1-2>||owrite<2|1>||progres<> GLOBALDOWNL0<a> GLOBALDOWNL<a> GLOBALDOWNL1<a> GLOBALDOWNL2<a> ;; содержимое всех страниц интернет ссылок из буфера обмена сохранить в активную панель в создаваемые именные папки сайтов в именные файлы сайтов + закачать все ссылки из созданных файлов в соответствующие папки

exect=$var_put=##@[tc=AP] sends=-1??-1||formt<54,63> urlxt=$GLOBALSENDS|4||$f254//9//Summa.txt||pause<1-2>||?Fvid13,1,6||delim<@CRLF!!1>||owrite<1> downl=$var_put//9||GLOBALURLXT<1>||convert<##@@e67::;;$$@@e73::;;?F63;;/!!\>||uformat<0>||pause<1-2>||owrite<2|1> tempxx ;; закачать в активную панель, в создаваемые папки из части url, найденные на страницах с контентом - видео файлы

exect=$var_put=##@[tc=AP]||$var_put=StringTrimRight('$var_put',1) sends=-1??-1||formt<54,1,63,6> slist=$GLOBALSENDS||#Hcrc32|1|1 downl=$var_put//9||$GLOBALSENDS||convert<##<listx=$GLOBALSLIST>\;;$$file-rndm[3-|8].;;$$@@e71::>||uformat<0>||owrite<2|1>||pause<1-2>||progres<> ;; закачать список ссылок из буфера в создаваемые папки из значений ссылок в виде хеша crc32, в активной панели со случайными именами

forpgs slist=FOLDC<%WL//1//1//*txt> xlist=$GLOBALSLIST||&&[^\\]+$!! <FOR> 1 <TO> GLOBALSLIST<0> downl=GLOBALXLIST<:INDEX:>||GLOBALSLIST<:INDEX:> <NEXT> ;; в выделенных папках по списку ссылок файлов *.txt скачать контент с расположением рядом с файлом - источником ссылки

global downl="%P"//1||%P%N||convert<&&(.+/)([^/]+/[^/]+)$!!$2>||progres<> renms=$GLOBALDOWNL||**!! renms=$GLOBALRENMS||extplus<>||upd<1> ;; скачать ссылки в активную панель из списка под курсором, добавив к имени первую "папку", после скачивания удалить расширения, и присвоить расширения по содержимому

global downl="%p"//1||cliplist||pause<1-5>||progres<>||metod<1> downl="%p"//1||$GLOBALDOWNL2||pause<1-5>||progres<>||upd<1> ;; скачивание списка ссылок из буфера обмена в текущую панель, добавлять счётчик при совпадении имён, каждая следующая закачка происходит со случайной задержкой от 1 до 5 секунд (используется объект MSXML2.XMLHTTP) + не закаченные ссылки добавляются для повторного скачивания обычным методом

global downl="%p"//2||cliplist||limit<0|3|5K|15K> GLOBALDOWNL1<a> GLOBALDOWNL2<a> ;; скачивание списка ссылок из буфера обмена в текущую панель, заменять при совпадении имён, закачиваются файлы, размер которых в диапазоне от 5 до 10 килобайт; получить списки скаченных файлов и не скаченных ссылок в глобальные переменные

global downl="%p"//2||cliplist||progres<> GLOBALDOWNL0<a> GLOBALDOWNL<a> GLOBALDOWNL1<a> GLOBALDOWNL2<a> GLOBALDOWNL3<a> ;; скачать список ссылок из буфера обмена в текущую панель, заменять при совпадении имён и получить списки скаченных файлов и не скаченных ссылок в глобальные переменные

global urlra=C:\link.txt|4||"%p"//0||formt<6,1!!(.*\.gif|.*\.bmp|.*\.png|.*\.jpg[^\r\n]*)>||convert<##<listx=C:\Name.txt>>||progres<> downl=@//9||listu<$GLOBALURLRA1>||pause<1-2>||progres<> ;; содержимое всех страниц интернет ссылок из файла C:\link.txt сохранить в активную панель в именные файлы из C:\Name.txt (извлечь все ссылки заданных типов) и закачать все ссылки в папки рядом с файлами списков

global urlra=cliplist|4||"%p"//0||formt<6,1!!(.*\.gif|.*\.bmp|.*\.png|.*\.jpg[^\r\n]*)>||convert<##<listx=C:\Name.txt>>||progres<> downl=@//9||listu<$GLOBALURLRA1>||pause<1-2>||progres<> ;; содержимое всех страниц интернет ссылок из буфера обмена сохранить в активную панель в именные файлы из C:\Name.txt (извлечь все ссылки заданных типов) и закачать все ссылки в папки рядом с файлами списков

imgpr=%%COMMANDER_PATH%%\Dance.gif bufsr=##http<clpget>||formt<6,1> downl="%p"//2||cliplist||pause<1-3> ;; закачать все ссылки со страницы (ссылка которой в буфере) в текущую панель и обновить + отображать заданное в параметре изображение во время работы утилиты

imgpr=1 bufsr=##http<clpget>||formt<6,1> downl="%p"//2||cliplist||pause<1-3> ;; закачать все ссылки со страницы (ссылка которой в буфере) в текущую панель и обновить + отображать изображение во время работы утилиты

imgpr=1 sends=-1||formt<insta0> sends=#GLOBALSENDS<1>!!-1||\/!!/||formt<insta1> downl="%p"//2||$GLOBALSENDS||progres<>||upd<1> ;; загрузить в активную панель все фотографии JPG ссылки с instagram из буфера обмена

imgpr=1 sends=-1||formt<insta0> sends=#GLOBALSENDS<1>!!-1||\/!!/||formt<insta2> downl="%p"//2||$GLOBALSENDS||progres<>||upd<1> ;; загрузить в активную панель большие фотографии n.JPG ссылки с instagram из буфера обмена

imgpr=1 sends=-1||formt<insta0> sends=#GLOBALSENDS<1>!!-1||\/!!/||formt<insta3> downl="%p"//2||$GLOBALSENDS||progres<>||upd<1> ;; загрузить в активную панель все фотографии JPG и видео MP4 ссылки с instagram из буфера обмена

imgpr=1 sends=-1||formt<insta0> sends=#GLOBALSENDS<1>!!-1||\/!!/||formt<insta4> downl="%p"//2||$GLOBALSENDS||progres<>||upd<1> ;; загрузить в активную панель большие фотографии n.JPG и видео n.MP4 ссылки с instagram из буфера обмена

itray=3 exect=$var_put=##@[tc=AP] sends=-1??-1||formt<54,1,63> slist=$GLOBALSENDS||#Hmd5|1|1||$$\ downl=$var_put//1||$GLOBALSENDS||convert<##<listx=$GLOBALSLIST>;;$$test.html>||uformat<0> ;; Из ссылок в буфере, вычислить контрольную сумму и закачать все файлы с присваиваемым именем test + расширение html в создаваемые каталоги из этой контрольной суммы

itray=3 sends=-1??-1||?F6 stylp=#2||Download downl=[tc=AP]//9||$GLOBALSENDS||sagent<W4>||pause<2-4>||owrite<2|1>||progres<>||upd<1> ;; загрузить в активную панель ссылки из буфера обмена

itray=3 sends=-1??-1||formt<lin44,lin37,1> downl="%p"//1||$GLOBALSENDS||pause<1-2>||progres<>||convert<#Slin40> renms=$GLOBALDOWNL||**!! renms=$GLOBALRENMS||extplus<> iconv=$GLOBALRENMS||"%p//1"||48,32,24,16||upd<1> ;; скачать из списка ссылок в буфере все иконки favicon.ico в активную панель, с конвертацией в размер 48,32,24,16 с сохранением имени из URL и удалением скачанных файлов

itray=3 sends=-1??-1||formt<lin44,lin37,1> downl="%p"//2||$GLOBALSENDS||convert<#Slin40>||upd<1> ;; скачать из списка ссылок в буфере все иконки favicon.ico в активную панель

itray=3 sends=-1??-1||formt<lin44,lin60,lin61,lin62,lin37,1> slist=$GLOBALSENDS||formt<lin58,lin57> downl="%p"//1||$GLOBALSENDS||pause<1-2>||progres<>||convert<#Hmd5> renms=$GLOBALDOWNL||extplus<> pause=500 iconv=$GLOBALRENMS||"%p//1"||32 renms=$GLOBALICONV||list<$GLOBALSLIST>||rflag<1> delss=$GLOBALDOWNL||1||upd<1> ;; загрузка всех иконок из списка URL в буфере с конвертацией в размер 32х32 в активную панель и преобразованием имени в адрес ссылки

itray=3 sends=-1??-1||formt<lin44,lin60,lin61,lin62,lin37,1> wlist=$GLOBALSENDS||formt<lin59,lin57> slist=$GLOBALSENDS||formt<lin58,lin57> downl="%p"//1||$GLOBALSENDS||pause<1-2>||progres<>||convert<#Hmd5> pause=500 renms=$GLOBALDOWNL||extplus<> lists=$GLOBALRENMS iconv=$GLOBALRENMS||"%p":://1//(.*)(\w:.*\\)([^\\]*)\.(.*)//$1$3||32 xlist=$GLOBALICONV||##<info=o76:://> renms=$GLOBALICONV||list<$GLOBALSLIST>||rflag<1> pause=500 renms=$GLOBALXLIST||list<$GLOBALWLIST> delss=$GLOBALLISTS||1 slist=FOLDC<$GLOBALRENMS//1//0//*.ico//0>||##<info=o75:://> pause=500 icofs=$GLOBALSLIST||0||ico,0,1 attrb=FOLDC<$GLOBALSLIST//1//0//*.ico//0>||+HS!!0||upd<1> ;; создание каталогов и назначение им иконок из списка ссылок в буфере

itray=3 sends=-1??-1||formt<lin44,lin60,lin61,lin62,lin37,1> wlist=$GLOBALSENDS||formt<lin59,lin57> slist=$GLOBALSENDS||formt<lin58,lin57> downl="%p"//1||$GLOBALSENDS||pause<1-2>||progres<>||convert<#Hmd5> pause=500 renms=$GLOBALDOWNL||extplus<> lists=$GLOBALRENMS iconv=$GLOBALRENMS||"%p":://1//(.*)(\w:.*\\)([^\\]*)\.(.*)//$1$3||32 xlist=$GLOBALICONV||##<info=o76:://> renms=$GLOBALICONV||list<GLOBALSLIST<t>>||rflag<1> pause=500 renms=$GLOBALXLIST||list<GLOBALWLIST<t>> delss=$GLOBALLISTS||1 slist=FOLDC<GLOBALRENMS<t>//1//0//*.ico//0>||##<info=o75::> pause=500 icofs=GLOBALSLIST<t>||0||ico,0,1 attrb=FOLDC<GLOBALSLIST<t>//1//0//*.ico//0>||+HS!!0||upd<1> ;; создание каталогов и назначение им иконок из списка ссылок в буфере

sends=#-1!!-1||formt<6,1!!(.*\.swf[^\r\n]*)> downl="%p"//2||$GLOBALSENDS||progres<> ;; скачать с содержимого страницы интернета (ссылки из буфера обмена) swf файлы в активную панель

sends=#-1??-1||formt<6,1!!(.*\.gif|.*\.png|.*\.jpg[^\r\n]*)> downl=$f254//2||$GLOBALSENDS||progres<> copys=$GLOBALDOWNL||"%P"//0||test<1r!!100K>||upd<1> ;; с интернет страницы, адрес которой из буфера получить список всех адресов изображений gif, png, jpg; скачать во временную папку и после скопировать в активную панель те файлы, которые более 100 Kb

sends=#-1??-1||formt<6,1!!(.*\.gif|.*\.png|.*\.jpg[^\r\n]*)> downl=$f254//2||$GLOBALSENDS||progres<> GLOBALDOWNL<a> ;; с интернет страницы, адрес которой из буфера получить список всех адресов изображений gif, png, jpg; скачать во временную папку и получить список скаченных файлов в глобальную переменную

sends=#-1\\4??-1||formt<6,1!!(?m)^(.*\.png|.*\.jpg|.*\.jpeg)$> downl="%p"<info=n3|Line1|8>\//1||$GLOBALSENDS||limit<0|1|20K>||progres<>||upd<1> ;; с интернет страницы, адрес которой из буфера обмена получить список всех адресов изображений png, jpg, jpeg; скачать активную панель в создаваемую папку со случайным именем (имя цифрами, длина 8 символов); закачиваются изображения, размер которых более 20 килобайт

sends=#-1\\4??-1||formt<6,1!!(?m)^(.*\.png|.*\.jpg|.*\.jpeg)$> downl="%p"<info=n3|Line1|8>\//1||$GLOBALSENDS||test<0n!!450px_>||limit<0|1|20K>||progres<>||upd<1> ;; с интернет страницы, адрес которой из буфера обмена получить список всех адресов изображений png, jpg, jpeg; скачать активную панель в создаваемую папку со случайным именем (имя цифрами, длина 8 символов); закачиваются изображения, размер которых более 20 килобайт; не загружать ссылки в именах которых есть фрагмент "450px_"

sends=-1??-1 downl="%p"//4||$GLOBALSENDS||convert<#Ssp304>||uformat<0>||upd<1> ;; скачивание списка ссылок из буфера обмена в текущую панель с созданием структуры папок ссылки

sends=-1??-1||formt<0!!([^/]+)> aends=#-1\\4!!-1||formt<6,1!!(?m)^(.*\.jpg|.*\.jpeg)$> downl="%p"\GLOBALSENDS<4>\//1||$GLOBALAENDS||limit<0|1|20K>||progres<>||upd<1> ;; загрузить в активную панель, в папку с названием товара, все фотографии JPG и JPEG (которые больше 20кб) ссылки с ebay.com из буфера обмена

sends=-1??-1||formt<1,lin36,lin37> downl="%p"//4||$GLOBALSENDS||convert<#Slin40>||upd<1> forpgs slist=GLOBALDOWNL<t> <FOR> 1 <TO> GLOBALSLIST<0> start=Magick||GLOBALDOWNL<:INDEX:>||-resize||32x32!||-normalize||-quality||90||"%p"Icons-32x32-<info=o72GLOBALDOWNL<:INDEX:>//>.ico||&&hide||&&wait <NEXT> ;; закачать из списка URL адресов в буфере (например http://rambler.ru/ или http://rambler.ru) иконки с сайтов (если такие имеются) в активную панель + переименовать в имя сайта + конвертация в размер 32х32

sends=-1??-1||formt<1,lin36,lin37> downl="%p"//4||$GLOBALSENDS||convert<#Slin40>||upd<1> ;; закачать иконки favicon.ico для списка ссылок сайтов из буфера обмена в активную панель с соответствующим именем сайта

slist=[tc=AM] <FOR> 1 <TO> GLOBALSLIST<0> exect=$var_i=<info=o9%%TCIMG_TEMP%%\link-font.txt//> $FORCONT=$var_i=2?0:1 downl=GLOBALSLIST<:INDEX:>fonts//2||%%TCIMG_TEMP%%\link-font.txt||pause<1-2>||progres<> <NEXT> ;; если файл link-font.txt со списком ссылок существует в папке TCIMG_TEMP то тогда начать закачку по списку и сохранить данные в папке fonts

slist=cliplist||test<1e!!png|jpg|gif> downl="%P"//1||$GLOBALSLIST||convert<##<listx=C:\Name.txt>>||uformat<0> ;; скачивание списка ссылок gif, png, jpg из буфера обмена в текущую панель, в именные файлы из списка C:\Name.txt

xends=-1 sends=#GLOBALXENDS<1>||#Sht1||?T|a,1:-1!!GLOBALXENDS<1> downl="%p"//1||$GLOBALSENDS||progres<> ;; из структурного web-адреса прочитать страницу получить все файлы между тегом href, добавить к найденному web-адрес и скачать в текущую панель


© Аверин Андрей для Total Commander Image  Averin-And@yandex.ru