Описание команды


Запуск команд, в зависимости от зажатых клавиш до вызова.
<HOTKEY=...> ... <HOTKEY=...> ... <HOTKEY=X> ...

<HOTKEY=HotKey1> commands1 <HOTKEY=HotKey2> commands2 ... <HOTKEY=HotKeyN> commandsN <HOTKEY=X> commandsX

Параметры:

<HOTKEY=HotKey1>Тег. HotKey1 - значение или значения клавиш, прописанных через запятую.
Каждому значению через дефис может быть прописано количество миллисекунд (если клавиша будет зажата заданное количество миллисекунд, то будет выполнены команды commands1).
commands1Строка команд. Команда(ы) выполняются если зажата(ы) клавиши HotKey1
<HOTKEY=HotKey2>Тег. HotKey2 - значение или значения клавиш, прописанных через запятую.
Каждому значению через дефис может быть прописано количество миллисекунд (если клавиша будет зажата заданное количество миллисекунд, то будет выполнены команды commands2)
commands2Строка команд. Команда(ы) выполняются если зажата(ы) клавиши HotKey2
......
<HOTKEY=HotKeyN>Тег. HotKeyN - значение или значения клавиш, прописанных через запятую.
Каждому значению через дефис может быть прописано количество миллисекунд (если клавиша будет зажата заданное количество миллисекунд, то будет выполнены команды commandsN)
commandsNСтрока команд. Команда(ы) выполняются если зажата(ы) клавиши HotKeyN
<HOTKEY=X>Тег. X после которого выполняется команда commandsX.
commandsXСтрока команд. Команда(ы) выполняются если НЕ зажата(ы) ни один из заданных наборов клавиш HotKey1 ... HotKeyN

Примечания:

• Теги и команды <HOTKEY=...> прописываются через пробел.
• Команды (commandsN) и их параметры имеют тот же синтаксис, что и в примерах.
• Значения клавиш см. Дополнение №3
• При совпадении значений клавиш в разных <HOTKEY=...>, те HotKey, которые используют несколько значений в командной строке должны быть прописаны раньше остальных:

<HOTKEY=10,11,12> ... <HOTKEY=10,11> ... <HOTKEY=10> ...


<HOTKEY=10-500,11-500,12-500> ... <HOTKEY=10-1000,11-1000> ... <HOTKEY=10-2000> ...

См. также:

anf2d, arr2d, asave, cmd64, cmdcm, cname, cycles, dilog, dubls, envgt, global, ifthen, inbox, listx, macro, noglob, pause, pressy, presww, renew, scrpt, sends, slects, slist, swcmd, swcths, tempxx, tempz, timess, zmenu, zmenz

Примеры:
 Как создать кнопку?

<HOTKEY=01-2000> infbx=||LEFT||3||100||40 <HOTKEY=X> infbx=||НЕТ||3||100||40 ;; пример запуска команд при зажатой клавиши ЛКМ 2000 мс (при запуске команды ЛКМ придётся сделать длинный второй клик)[hotkiy]

<HOTKEY=02> beepss sends=@<info=x50> copyy=GLOBALSENDS<1>.bakp||x//1||&&\.bakp$!!||**2!! <HOTKEY=X> sends=@<info=x50> copyy=GLOBALSENDS<1>||x!!1||**1!!?.bakp barsf=2||GLOBALSENDS<1> textt=GLOBALSENDS<1>||&&(menu)(\d+)(=[^\r\n]*)!!$1$2$3~~($2) ;; ЛКМ - В конце подсказок всех кнопок текущей панели инструментов вывести номера кнопок, предварительно создав бэкап *.bar.bakp | ПЛКМ - восстановить текущую панель инструментов из бэкапа

<HOTKEY=02> bufsr=@@QWERTYinRUS!!1 <HOTKEY=X> renms=%WL||@@QWERTYinRUS!!1||upd<1> ;; ЛКМ - переименовать базовое имя выделенных объектов - произвести исправление неправильной раскладки клавиатуры с английской в русскую|ПЛКМ - в буфере обмена произвести исправление неправильной раскладки клавиатуры с английской в русскую

<HOTKEY=02> moves=%WL||"%p"[Прочитано]||upd<1> <HOTKEY=X> moves=%WL||"%p"[Просмотрено]||upd<1> ;; ЛКМ - переместить выделенные объекты в папку [Просмотрено]|ПЛКМ - переместить выделенные объекты в папку [Прочитано]

<HOTKEY=02> renms=%WL||#Sfnc_numminus0||[double]||upd<1> <HOTKEY=X> renms=%WL||#Sfnc_numplus0||[double]||upd<1> ;; ЛКМ - в именах выделенных объектов увеличить числа на 1|ПЛКМ - уменьшить числа на 1

<HOTKEY=10,11> infbx=||CTRL+SHIFT||3||120||40 <HOTKEY=11,12> infbx=||CTRL+ALT||3||120||40 <HOTKEY=10,12> infbx=||SHIFT+ALT||3||120||40 <HOTKEY=X> infbx=||НИЧЕГО||3||100||40 ;; пример запуска команд при зажатых клавишах

<HOTKEY=10> barsw=v%%COMMANDER_PATH%%\Audio_V.bar||SwitchBarV <HOTKEY=11> barsw=%%COMMANDER_PATH%%\Bar\Audio.bar||SwitchBarG <HOTKEY=X> barsw=%%COMMANDER_PATH%%\Bar\Audio.bar||SwitchBarG barsw=v%%COMMANDER_PATH%%\Audio_V.bar||SwitchBarV ;; удерживая Shift открывается на вертикальной панели инструментов Audio_V.bar, удерживая Ctrl на горизонтальной панели инструментов открывается Audio.bar, обычное нажатие на кнопку открываются одновременно 2 ранее указанные панели

<HOTKEY=10> copys=%WL||"%t"//0||$$_[info=s30]||upd<3> <HOTKEY=11> copys=%WL||"%t"//0||^^[info=s30]_||upd<3> <HOTKEY=X> copys=%WL||"%t"//0||^^cntr<1+|1|2>_||upd<3> ;; копирование выделенных объектов в неактивную панель:|ЛКМ - с добавлением нумерации в начало имён|Shift+ - с добавлением даты в конец имён |Ctrl+ - с добавлением даты в начало имён

<HOTKEY=10> copys=%WL||"%t"//0||$$_[info=s30]||upd<3> <HOTKEY=11> copys=%WL||"%t"//0||^^[info=s30]_||upd<3> <HOTKEY=X> copys=%WL||"%t"//0||^^cntr<1+|1|2>_||upd<3> ;; копирование выделенных объектов в неактивную панель:|ЛКМ - с добавлением нумерации в начало имён|Shift+ - с добавлением даты в конец имён|Ctrl+ - с добавлением даты в начало имён

<HOTKEY=10> creat="%p"||Name.html <HOTKEY=11> creat="%p"||Name.au3 <HOTKEY=12> creat="%p"||Name.vbs <HOTKEY=X> creat="%p"||Name ;; при зажатой клавише Shift создаётся файл Name.html, при зажатой Ctrl - Name.au3, при зажатой Alt - Name.vbs, в обычном режиме Name.txt

<HOTKEY=10> imgpr=1 slist=%WL start=BATtoEXE||-bat||%P%N||-save||[tc=AO].exe||-icon||GLOBALSLIST<1>||-upx||-invisible||upd<1> <HOTKEY=X> imgpr=1 slist=%WL start=BATtoEXE||-bat||%P%N||-save||[tc=AO].exe||-icon||GLOBALSLIST<1>||upd<1> ;; конвертировать*.bat под курсором в *.exe с тем же именем со значком выделенного *.ico в активной панели (с Shift невидимое)

<HOTKEY=10> imgpr=1 start=BATtoEXE||-bat||%P%N||-save||[tc=AO].exe||-icon||[tc=TQ]||-upx||-invisible||upd<1> <HOTKEY=X> imgpr=1 start=BATtoEXE||-bat||%P%N||-save||[tc=AO].exe||-icon||[tc=TQ]||upd<1> ;; конвертировать*.bat под курсором в *.exe с тем же именем со значком выделенного *.ico в неактивной панели (с Shift невидимое)

<HOTKEY=10> imgpr=1 start=BATtoEXE||-bat||%P%N||-save||[tc=AO].exe||-icon||clpget||-invisible||upd<1> <HOTKEY=X> <HOTKEY=10> imgpr=1 start=BATtoEXE||-bat||%P%N||-save||[tc=AO].exe||-icon||clpget||upd<1> ;; конвертировать*.bat под курсором в *.exe с тем же именем со значком из буфера обмена (с Shift невидимое)

<HOTKEY=10> infbx=||SHIFT||3||100||40 <HOTKEY=11> infbx=||CTRL||3||100||40 <HOTKEY=12> infbx=||ALT||3||100||40 <HOTKEY=X> infbx=||НИЧЕГО||3||100||40 ;; пример запуска команд при зажатых клавишах

<HOTKEY=10> iniwr=%%TCIMG_PATH%%\TCIMGU.ini||Navigation||Path||"%P" <HOTKEY=X> exect=$var_path=##$INI<8//%%TCIMG_PATH%%\TCIMGU.ini//Navigation//Path> patha=$var_path ;; по зажатой клавише SHIFT запомнить путь активной панели; Простое нажатие - переход по запомненному пути

<HOTKEY=10> tcimg=$cm3304 <HOTKEY=11> tcimg=$cm3305 <HOTKEY=12> desel=10 <HOTKEY=X> tcimg=$cm524 ;; снять всё выделение. При зажатой SHIFT - снять выделение с файлов. При зажатой CTRL - снять выделение с папок. При зажатой ALT - снять выделение в обеих панелях.

<HOTKEY=11> bufsr=^^||save<"%p"x.txt|0>||first<>||upd<1> <HOTKEY=02> dilog=[updwn=BOX_U5] creat="%p"||GLOBALUPDWN1<1>.GLOBALUPDWN1<2>||bkt<!!_!!!!1!!1>||numb<GLOBALUPDWN1<3>> <HOTKEY=10> creat="%p"||list<clpget>||upd<1> <HOTKEY=X> dilog=[updwn=BOX_U4] creat="%p"||GLOBALUPDWN1<1>.GLOBALUPDWN1<2>||clip<>||upd<1> ;; ЛКМ - Создать файл с содержимым буфера обмена|ПЛКМ - создание файлов|Shift+ - создание файлов по списку |Ctrl+ - создать файл с содержимым буфера обмена именем первой строки

<HOTKEY=11> clink=%WL||noext<all> <HOTKEY=10> clink=%WL||"%t"//0||noext<all> <HOTKEY=X> clink=%WL||"%p"//0||noext<all> ;; ЛКМ - Создать ярлыки выделенным объектам в активной панели|Shift+ - Создать ярлыки выделенным объектам в неактивной панели|Ctrl+ - Создать ярлыки выделенным объектам на рабочем столе

<HOTKEY=11> copys=%WL||"%t"//0||##clpget||upd<3> <HOTKEY=10> renms=%WL||list<clpget*?>||upd<1> <HOTKEY=X> renms=%WL||##clpget||upd<1> ;; ЛКМ - Переименовать ВО именем из БО|Shift+ - Переименовать ВО по списку имён из БО|Ctrl+ - Копировать ВО в ДП с заменой базовых имён на имя из БО

<HOTKEY=11> shape=1 slist=[tc=AG] creat="%p"||[combo=BOX2].[combo=BOX3]||content<$GLOBALSLIST> <HOTKEY=10> shape=1 slist=[tc=TG] creat="%p"||[combo=BOX2].[combo=BOX3]||content<$GLOBALSLIST> <HOTKEY=X> shape=1 creat="%p"||[combo=BOX2].[combo=BOX3] ;; ЛКМ - создать в АП файл, имя и расширение выбираются в ДО|Ctrl+ - создать в АП файл с содержимым - "имена ВО в АП"|Shift+ - создать в АП файл с содержимым - "имена ВО в ПП"

<HOTKEY=11> shape=51 thumb=[combo=Размер~~эскизов||Выбрать~~размер~~ширины~~эскиза||80|100|120|140|160|180|200|300|320||280||120||1||0]||[combo=Размер~~эскизов||Выбрать~~размер~~высоты~~эскиза||70|80|90|100|120|140|160|200|220||280||120||1||0] <HOTKEY=X> tcimg=$cm269 ;; если зажата CTRL, то запустить диалог установки размеров эскизов, если нет, то включить/выключить режим "Эскизы" в Total Commander

<HOTKEY=11> start=notepad <HOTKEY=X> start=notepad||%P%N ;; открыть файл под курсором в блокноте, если зажата клавиша CTRL, то открыть блокнот

<HOTKEY=11> start=Restorator||%P%N||&&focus <HOTKEY=X> start=Restorator ;; при зажатой клавише CTRL открыть файл под курсором в программе Restorator, если не зажата, то запустить программу

<HOTKEY=11> tcimg=$pm_Creat_Folder_T <HOTKEY=x> tcimg=$pm_Creat_Folder_P ;; если зажата клавиша CTRL, то создать папки в неактивной панели, если не зажата, то в активной


© Аверин Андрей для Total Commander Image  Averin-And@yandex.ru