WinList

首页后退前进

WinList

获取窗口标题与句柄列表.

WinList ( ["title" [, "text"]] )

参数

title	[可选] 目标窗口标题, 或句柄, 或类名. 参考窗口标题与文本.
text	[可选] 目标窗口文本. 默认值为空字符串. 参考窗口标题与文本.

返回值

返回窗口标题和句柄的数组.

备注

若没有指定"title"及"text"参数, 则返回所有顶层窗口的相关信息.

本函数返回一个二维数组, 包含下列信息:

$aArray[0][0] = 窗口数

$aArray[1][0] = 第 1 个窗口的标题

$aArray[1][1] = 第 1 个窗口的句柄 (HWND)

$aArray[2][0] = 第 2 个窗口的标题

$aArray[2][1] = 第 2 个窗口的句柄 (HWND)

...

$aArray[n][0] = 第 n 个窗口的标题

$aArray[n][1] = 第 n 个窗口的句柄 (HWND)

函数示例

示例 1

#include <MsgBoxConstants.au3>
Example()
Func Example()
    ; Retrieve a list of window handles.
    Local $aList = WinList()
    ; Loop through the array displaying only visable windows with a title.
    For $i = 1 To $aList[0][0]
        If $aList[$i][0] <> "" And BitAND(WinGetState($aList[$i][1]), 2) Then
            MsgBox($MB_SYSTEMMODAL, "", "Title: " & $aList[$i][0] & @CRLF & "Handle: " & $aList[$i][1])
        EndIf
    Next
EndFunc   ;==>Example

示例 2

#include <Array.au3>
Example()
Func Example()
    ; Retrieve a list of window handles using a regular expression. The regular expression looks for titles that contain the word SciTE or Internet Explorer.
    Local $aWinList = WinList("[REGEXPTITLE:(?i)(.*SciTE.*|.*Internet Explorer.*)]")
    _ArrayDisplay($aWinList)
EndFunc   ;==>Example

----------------------------------------

该函数可以通过命令调用 exect

参见:

WinGetState, WinGetHandle

例子

如何创建一个按钮?

exect=_ViewValues(nlist.htm">WinList()) ;;从窗口描述符的标题</ s>获取数组