IniRead

首页后退前进

IniRead

读配置文件(*.ini)的值.

IniRead ( "filename", "section", "key", "default" )

参数

filename	目标 .ini 文件名.
section	.ini 文件中的字段名.
key	.ini 文件中的关键字名称.
default	若未发现指定的关键字, 则函数将返回此默认值.

返回值

成功:	返回请求关键字的值.
失败:	若指定的关键字的值未发现, 则函数将返回参数"默认值"设置的值.

备注

标准 INI 文件结构如下:

[字段名]

关键字=值

所有返回的值转换为字符串. 因此如果您需要一个整数, 例如 1000, 则使用 Int() 或 Number(), 同样的, 如果需要一个 hwnd (句柄)指针, 则使用 Ptr() 或 HWnd().

函数示例

#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>
Example()
Func Example()
    ; Create a constant variable in Local scope of the filepath that will be read/written to.
    Local Const $sFilePath = _WinAPI_GetTempFileName(@TempDir)
    ; Write the value of 'AutoIt' to the key 'Title' and in the section labelled 'General'.
    IniWrite($sFilePath, "General", "Title", "AutoIt")
    ; Read the INI file for the value of 'Title' in the section labelled 'General'.
    Local $sRead = IniRead($sFilePath, "General", "Title", "Default Value")
    ; Display the value returned by IniRead.
    MsgBox($MB_SYSTEMMODAL, "", "The value of 'Title' in the section labelled 'General' is: " & $sRead)
    ; Delete the key labelled 'Title'.
    IniDelete($sFilePath, "General", "Title")
    ; Read the INI file for the value of 'Title' in the section labelled 'General'.
    $sRead = IniRead($sFilePath, "General", "Title", "Default Value")
    ; Display the value returned by IniRead. Since there is no key stored the value will be the 'Default Value' passed to IniRead.
    MsgBox($MB_SYSTEMMODAL, "", "The value of 'Title' in the section labelled 'General' is: " & $sRead)
    ; Delete the INI file.
    FileDelete($sFilePath)
EndFunc   ;==>Example

----------------------------------------

该函数可以通过命令 exect 调用

参见:

IniDelete, IniWrite, FileReadLine, IniReadSection, IniReadSectionNames, IniRenameSection, IniWriteSection

例子

如何创建一个按钮?

exect=$var_s=IniRead(EnvGet('COMMANDER_INI'),'WWW','Key','#')||_ViewValues('$var_s') ;; 从从Wincmd.ini文件的[WWW]字段中检索键值值

exect=$var_a=StringSplit('%%COMMANDER_PATH%%\Bar\000_TCIMG_Test.bar|%%COMMANDER_PATH%%\Bar\084_AU3.bar|%%COMMANDER_PATH%%\Bar\000_TCIMG_Test_Exe.bar','|')||$var_si=EnvGet('COMMANDER_PATH')&'\WinButtonBar.ini'||$var_sb=IniRead('$var_si','Buttonbar','Buttonbar','''')||$var_i=Number(_ArraySearch($var_a,'$var_sb')+1)||$var_i=($var_i>3~~Or~~$var_i=0)?1:$var_i||IniWrite('$var_si','Buttonbar','Buttonbar','$var_a[$var_i]')||IniWrite('$var_si','Buttonbar','Buttonbar',Execute('$var_a[$var_i]')) ;; 将WinButtonBar.ini中的一个圆圈中的3个预定义的.bar路径之一写入[Buttonbar]字段

exect=$var_a=StringSplit(StringReplace('??%%COMMANDER_PATH%%\TCIMG.exe?~~?openup??|??%%COMMANDER_PATH%%\Utilities\TotalCom\ChoiceEditor\ChoiceEditor.exe??','?',Chr(34)),'|')||$var_sc=EnvGet('COMMANDER_INI')||$var_sp=IniRead('$var_sc','Configuration','Editor','''')||$var_is=StringInStr('$var_sp','TCIMG')?2:1||IniWrite('$var_sc','Configuration','Editor',$var_a[$var_is]) rstart ;; 重新启动时切换到F4

"exect=$var_s=EnvGet('COMMANDER_PATH') GLOBALEXECT<a> IniRead($var_s&'\Wincmd.ini','Configuration','Editor','#') GLOBALEXECT<a>" - 从Wincmd.ini文件的[Configuration]字段中检索Editor键的值

exect=$var_s=IniRead(EnvGet('COMMANDER_INI'),'Configuration','SortUpper','0')