IniReadSectionNames

首页后退前进

IniReadSectionNames

读配置文件(*.ini)的全部字段信息.

IniReadSectionNames ( "filename" )

参数

filename

目标 .ini 文件名.

返回值

成功:	返回含有所有字段名的数组.
失败:	@error 设置为非 0 值.

备注

标准 INI 文件结构如下:

[字段名]

关键字=值

本函数返回的数组 $aArray[0] 中储存数组元素的数量. 如果出现 @error, 则该数组不会被创建.

函数示例

#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>
Example()
Func Example()
    ; Create a constant variable in Local scope of the filepath that will be read/written to.
    Local Const $sFilePath = _WinAPI_GetTempFileName(@TempDir)
    ; Create an INI section structure as a string.
    Local $sSection = "Title=AutoIt" & @LF & "Version=" & @AutoItVersion & @LF & "OS=" & @OSVersion
    ; Write the string to the sections labelled 'General', 'Version' and 'Other'.
    IniWriteSection($sFilePath, "General", $sSection)
    IniWriteSection($sFilePath, "Version", $sSection)
    IniWriteSection($sFilePath, "Other", $sSection)
    ; Read the INI section names. This will return a 1 dimensional array.
    Local $aArray = IniReadSectionNames($sFilePath)
    ; Check if an error occurred.
    If Not @error Then
        ; Enumerate through the array displaying the section names.
        For $i = 1 To $aArray[0]
            MsgBox($MB_SYSTEMMODAL, "", "Section: " & $aArray[$i])
        Next
    EndIf
    ; Delete the INI file.
    FileDelete($sFilePath)
EndFunc   ;==>Example

----------------------------------------

该函数可以通过命令 exect 调用

参见:

IniDelete, IniWrite, IniRead, IniReadSection, IniRenameSection, IniWriteSection

例子

如何创建一个按钮?

exect=$var_a=IniReadSectionNames(EnvGet('COMMANDER_INI'))||_ViewValues($var_a) ;; 读取Wincmd.ini中所有部分的名称